Groups sub menus on rigtmouseclick

[blake20]

Fellow members of this forum,

I don't now how to make a group sub menu on a rigtmouseclick.

I am using the following [CODE}

Public Sub MuisMenuToevoegen()
'maak menu klaar voor or make menu
Call MuisMenuVerwijderen 'call to remove mousemenu rigtmouseclick

With Application.CommandBars("cell").Controls
' Begin group and let first parting line stand

With .Add(Type:=msoControlButton, Before:=1, temporary:=True)
.Visible = False
.BeginGroup = True
End With


'repeat code between the stars for a next menu item.

'Use and fill caption an onaction on a good way
'****************************************************************************************
'Voeg een nieuw menu item toe

With .Add(Type:=msoControlButton, Before:=1, temporary:=True)
.Caption = "Start &LKV Formulier" 'text you see with you richtmouseclick
.OnAction = "ShowFormulier" 'The (sub) routine call
End With 'between quotes ""

With .Add(Type:=msoControlButton, Before:=1, temporary:=True)
.Caption = "Pas &Scherm aan"
.OnAction = "PasSchermAan"
End With

With .Add(Type:=msoControlButton, Before:=1, temporary:=True)
.Caption = "Kleur &Record"
.OnAction = "KleurRij"
End With

With .Add(Type:=msoControlButton, Before:=1, temporary:=True)
.Caption = "Start &Zoekscherm"
.OnAction = "ZoekScherm"
End With

With .Add(Type:=msoControlButton, Before:=1, temporary:=True)
.Caption = "Start &HelpScherm"
.OnAction = "Helpscherm"
End With

With .Add(Type:=msoControlButton, Before:=1, temporary:=True)
.Caption = "&Onwaar word NEE"
.OnAction = "OnWaarWordNee"
' .Visible = True
End With


With .Add(Type:=msoControlButton, Before:=1, temporary:=True)
.Caption = "&Waar word JA"
.OnAction = "WAARWordJa"
' .Visible = False
End With


'****************************************************************************************
'Dus hier volgende menu item
End With
End Sub

[CODE]

This works pure as menu items but how do i get this as a group sub menu parts.
I need to work with more than one group

See also the attachment.

[Bernie Deitrick]

You need to add a PopUp control first, then add the new controls to that pop-up. Here is the correct structure, but without all your code:

Public Sub MuisMenuToevoegen2()
    Application.CommandBars("cell").Reset
    'maak menu klaar voor or make menu
    With Application.CommandBars("cell").Controls
        ' Begin group and let first parting line stand
        
        'Add a control POPUP first
        With .Add(Type:=msoControlPopup, Before:=1, temporary:=True)
            .Caption = "My NEW Group!"
        
            'Then add controls to the popup control
            With .Controls.Add(Type:=msoControlButton, Before:=1, temporary:=True)
                .Caption = "Start &LKV Formulier" 'text you see with you richtmouseclick
                .OnAction = "ShowFormulier" 'The (sub) routine call
            End With 'between quotes "
                
            With .Controls.Add(Type:=msoControlButton, Before:=1, temporary:=True)
                .Caption = "Pas &Scherm aan"
                .OnAction = "PasSchermAan"
            End With
                
            'And for the others
                
        End With
    End With
End Sub

[blake20]

Many thanks Bernie i wil try it