edit code for list box only have data

Hello mazan2010,

Please attach a sample workbook. Make sure there is just enough data to demonstrate your need. Include a BEFORE sheet and an AFTER sheet in the workbook if needed to show the process you're trying to complete or automate. Make sure your desired results are shown, mock them up manually if necessary.

Remember to desensitize the data.

Click on GO ADVANCED and then scroll down to Manage Attachments to open the upload window.

Try this.

Private Sub UserForm_Initialize()
'Macro Purpose: To populate a multi-column listbox with data from
'               a worksheet range
    
    Dim lbtarget As msforms.ListBox
    Dim rngSource As Range
    
    'Set reference to the range of data to be filled
    With Worksheets("Waiting list")
        Set rngSource = Worksheets("Waiting list").Range("A2:E" & .Range("A" & Rows.Count).End(xlUp).Row)
    End With
   'Fll the listbox
    Set lbtarget = Me.ListBox1
    With lbtarget
        'Determine number of columns
        .ColumnCount = 5
        'Set column widths
        .ColumnWidths = "100;20;50;50;20"
        'Insert the range of data supplied
        .List = rngSource.Cells.Value
    End With
    
End Sub

For the first part try this.

Private Sub UserForm_Initialize()
Dim I As Long

    'Macro Purpose: To populate a multi-column listbox with data from
    '               a worksheet range
    
    Dim lbtarget As msforms.ListBox
    Dim rngSource As Range
    
    'Set reference to the range of data to be filled
    With Worksheets("Waiting list")
        Set rngSource = Worksheets("Waiting list").Range("A2:E" & .Range("A" & Rows.Count).End(xlUp).Row)
    End With

   'Fll the listbox
    Set lbtarget = Me.ListBox1

    With lbtarget
        'Determine number of columns
        .ColumnCount = 5
        'Set column widths
        .ColumnWidths = "100;20;50;50;20"
        'Insert the range of data supplied
        .List = rngSource.Cells.Value
        For I = 0 To .ListCount - 1
            .List(I, 4) = Trim(rngSource.Cells(I + 1, 5).Text)
        Next I
    End With
    
End Sub

Not sure about the second part, what do you want to base the column widths on?

This line is setting the widths of the 5 columns, in points (pts)W, in the listbox.

.ColumnWidths = "100;20;50;50;20"

It sets the first column to a width 100 pts, the second to 20 pts, the 3rd to 50 pts and so on.

What's the problem with the delete button?

If you just want to delete without a message try this.

Private Sub CommandButton1_Click()
Dim I As Long

    With ListBox1
        For I = .ListCount - 1 To 0 Step -1
            If .Selected(I) Then
                .RemoveItem I
                Sheets("Waiting list").Rows(I + 2).EntireRow.Delete
            End If
        Next I
    End With

End Sub

When I click the delete button the selected row is deleted from the listbox and the sheet.

Your message box can only return vbOk, not vbYes or anything else.

Not unless you use RowSource to populate the listbox.

No, I mean use the RowSource property of the listbox to populate the listbox.

There are 3 main ways to populate a listbox:

1 using the RowSource property

2 using List

3 using AddItem

For 1 you set the RowSource property of the listbox to a reference to the range you want to populate it with.

For example if you wanted to populate a listbox, ListBox1 from A1:D20 on Sheet1 you would set the RowSource property to Sheet1!A1:D20.

That can be done manually but here's the code to do it anyway.

ListBox1.RowSource = "Sheet1!A1:D20"

If you want headers in your listbox you have to use this method to populate it.