Merging col items in a single cell for each row item

Put this function in a standard code module

Function CONCATINATEIF(rngCrit As Range, strCrit As String, rngCONCAT As Range) As String
    Dim i As Long
    For i = 1 To rngCrit.Count
        If rngCrit(i).Value = strCrit Then CONCATINATEIF = CONCATINATEIF & rngCONCAT(i) & ", "
    Next i
    If Len(CONCATINATEIF) > 2 Then CONCATINATEIF = Left(CONCATINATEIF, Len(CONCATINATEIF) - 2)
End Function

Put this formula in Q2 and copy down

=CONCATINATEIF(B2:M2,"Matched",$B$1:$M$1)

Originally Posted by Rajkumar_h

Thanks Alpha Its working great. Can i ask you instead of Function can you help with using Array vba coding.

Sub Concat_Matched()
    Dim v As Variant, i As Long, j As Long, r As Variant
    v = Range("B1:M" & Range("A" & Rows.Count).End(xlUp).Row).Value
    ReDim r(1 To UBound(v, 1) - 1, 1 To 1)
    For i = 2 To UBound(v, 1)
        For j = 1 To UBound(v, 2)
            If v(i, j) = "Matched" Then r(i - 1, 1) = r(i - 1, 1) & v(1, j) & ", "
        Next j
        If r(i - 1, 1) <> Empty Then r(i - 1, 1) = Left(r(i - 1, 1), Len(r(i - 1, 1)) - 2)
    Next i
    Range("Q2").Resize(UBound(r, 1)).Value = r
End Sub

Check your data.

In row 12, D12 and I12 both say Matched (against 01CV and 01LA) but the result in Q12 only says 01CV ?
Q14 says 01BV but B14 (01BV) says Not matched. D14 (01CV) is in fact matched but theres no reference to this in Q14 ?
B15 Says Matched for 01BV but Q15 says 01FC which is not matched in that row ?
Row 16 is a complete mess, 01CV 01FF 01HT 01NW 01SL are all matched yet Q16 only has 01LA which is not matched at all ?
Row 17 check D17 and Q17 result
Row 18 check the Matched against Q18 results
Row 19 check it
Row 20 check it also
Row 21 again check this
Row 22 wrong again check it
Row 23 check it
Row 24 ....HOORAY! WE HAVE A WINNER, ITS FRIGGING CORRECT!!
Row 25 Here we go again, its wrong
Row 26 Not sure what you done here, check it
Row 27 wrong again
Row 28 ...WHY NOT END ON A CORRECT ROW! Thank god!

Why do we have to check people's data on this forum before solving a problem?
It should be correct in the first place!!