Creating an MD5 function

I need a function that can MD5 hash a string. This is what I have so far:

Public Function MD5Hex(textString As String) As String
  Dim enc
  Dim textBytes() As Byte
  Dim bytes
  Dim outstr As String

  Set enc = CreateObject("System.Security.Cryptography.MD5CryptoServiceProvider")
  textBytes = textString
  bytes = enc.ComputeHash_2(textBytes)

  For pos = 1 To LenB(bytes)
      outstr = outstr & LCase(Right("0" & Hex(AscB(MidB(bytes, pos, 1))), 2))
  Next
 
  MD5Hex = outstr
  Set enc = Nothing
  
  End Function

However, this is giving me the wrong hash. Does anyone know what the problem might be?

Code Tags Added
Your post does not comply with Rule 3 of our Forum RULES. Use code tags around code.

Posting code between [CODE] [/CODE] tags makes your code much easier to read and copy for testing, it also maintains VBA formatting.

Highlight your code and click the # icon at the top of your post window. More information about these and other tags can be found at http://www.excelforum.com/forum-rule...rum-rules.html



(I have added them for you today. Please take a few minutes to read all Forum Rules and comply in the future.)

By using VBA automatic data conversion, from string to array of bytes, like :

Dim textBytes() As Byte
textBytes = textString

the result (array of bytes), is in unicode format (2 bytes for each character).

You have to to discard every even bytes (only take the odd bytes), like this :

Public Function MD5Hex(textString As String) As String
  Dim enc
  Dim pos As Long
  Dim tempBytes() As Byte
  Dim textBytes() As Byte
  Dim bytes
  Dim outstr As String

  Set enc = CreateObject("System.Security.Cryptography.MD5CryptoServiceProvider")

  'textBytes = textString
  tempBytes = textString
  ReDim textBytes(0 To UBound(tempBytes) \ 2)
  For pos = 0 To UBound(textBytes)
      textBytes(pos) = tempBytes(pos * 2)
  Next pos

  bytes = enc.ComputeHash_2(textBytes)

  For pos = 1 To LenB(bytes)
      outstr = outstr & LCase(Right("0" & Hex(AscB(MidB(bytes, pos, 1))), 2))
  Next

  MD5Hex = outstr
  Set enc = Nothing

End Function

Sub Test()
  Debug.Print MD5Hex("Hello World")
End Sub

You are welcome.

If that takes care of your original question, please select Thread Tools from the menu link above and mark this thread as SOLVED. Thanks.

Unfortunately your post does not comply with Rule 2 of our Forum RULES. Do not post a question in the thread of another member -- start your own thread.

If you feel an existing thread is particularly relevant to your need, provide a link to the other thread in your new thread.

Old threads are often only monitored by the original participants. New threads not only open you up to all possible participants again, they typically get faster response, too.