Delete table rows in multiple table is specific range

[3345james]

Have a 13 Worksheet workbook
12 are like attached (1 per month)
Col A:Z contain tables that must be left alone

Col AA:AX contain 5 different tables (The same position on each worksheet)
Looking for a macro like below to delete any table row within these 5 tables that have a value of 0

This works well but I have to enter each table#

Sub DataTableDeleteRows()
Dim j As Long
    
    With ActiveSheet.ListObjects("Table15")
        For j = .ListRows.Count To 1 Step -1
            If .ListRows(j).Range(1, .ListColumns("Correct").Index) = "0" Then _
                .ListRows(j).Delete
        Next j
    End With
End Sub

Thanks for the assist
Jim

[CK76]

See if below works.

Sub DataTableDeleteRows()
Dim j As Long
Dim tbl As ListObject

For Each tbl In ActiveSheet.ListObjects
    If Len(Split(tbl.Range(, 1).Address, "$")(1)) > 1 Then
        With tbl
            For j = .ListRows.Count To 1 Step -1
                If .ListRows(j).Range(1, .ListColumns("Correct").Index) = "0" Then _
                    .ListRows(j).Delete
            Next j
        End With
    End If
Next
End Sub

[3345james]

This works great!
How are you telling it to only select AA:AX Tables?

Thanks

[CK76]

If Len(Split(tbl.Range(, 1).Address, "$")(1)) > 1 Then

Above if statement grabs address of first column of each table. Splits the returned string using "$".
Then grabs 2nd array element (i.e. Column letters) and checks for it's length and if it's greater than 1 character.

So, if table fell in A~Z range length returned will be 1, AA~ will be 2.

[3345james]

That's sweet!
Thanks for explaining