Open PowerPoint in slideshow mode from Excel

to run the slideshow you can use

Select Case Dir(s) <> ""
    Case True
        Set myPresentation = objPPT.Presentations.Open(s)
        myPresentation.SlideShowSettings.Run
    Case False
        MsgBox "Could not find file!", vbCritical, s
End Select

You could use the ontime event. Try this example.
Don't forget to change name of powerpoint file

Private m_pptApp As Object
Sub KillPPT()

    If Not m_pptApp Is Nothing Then
        If m_pptApp.SlideShowWindows.Count > 0 Then
            ' check again in 2 seconds
            Application.OnTime Now() + TimeSerial(0, 0, 2), "KillPPT"
        Else
            m_pptApp.activepresentation.Close
            m_pptApp.Quit
            Set m_pptApp = Nothing
            AppActivate Application.Caption
        End If
    End If
    
End Sub


Sub ShowPPT()

    Dim filename As String

    'Opens a PowerPoint presentation from Excel
    Dim s$
    Dim pres As Object
    
    s = "C:\temp\Presentation1.pptx"  '"D:\Dropbox\Jobs\NCDOT Financial Technical Assistance\Presentation1.pptx"
    
    Set m_pptApp = CreateObject("PowerPoint.Application")
    m_pptApp.Visible = True
    
    Select Case Dir(s) <> ""
    Case True
        Set pres = m_pptApp.Presentations.Open(s)
        pres.SlideShowSettings.Run
        
        Application.OnTime Now() + TimeSerial(0, 0, 2), "KillPPT"
    Case False
        MsgBox "Could not find file!", vbCritical, s
    End Select

End Sub

I only get an error if the powerpoint is shutdown by the user.
The error messages is

Application.ActivePresentation : Invalid request. There is no active presentation.


This tweak will check for open presentation

Sub KillPPT()

    If Not m_pptApp Is Nothing Then
        If m_pptApp.SlideShowWindows.Count > 0 Then
            ' check again in 2 seconds
            Application.OnTime Now() + TimeSerial(0, 0, 2), "KillPPT"
        Else
            If m_pptApp.presentations.Count > 0 Then
                m_pptApp.activepresentation.Close
            End If
            m_pptApp.Quit
            Set m_pptApp = Nothing
            AppActivate Application.Caption
        End If
    End If
    
End Sub

My pptx file shows and I can make my way through the slideshow. Once I get passed the 'click to end slide show' screen the Killppt routine executes within a couple of seconds to shutdown powerpoint and return focus to Excel.