Getting list of files from folder and subfolder

This will create a a list of folders and files in columns A and B of the active sheet - you can list any other file attributes you need in other columns.....

Dim FSO As Scripting.FileSystemObject
Dim lngR As Long

Sub ListFiles()
    FindFilesFromFolders "C:\Users\Me\SharePoint\Someone else\Shared_Folder"     'Change to desired parent folder
End Sub

Sub FindFilesFromFolders(strFolderName As String)
    Dim fsoFolder As Scripting.Folder

    If FSO Is Nothing Then
        Set FSO = New Scripting.FileSystemObject
    End If
    
    lngR = 1
    
    Set fsoFolder = FSO.GetFolder(strFolderName)
    FindFiles fsoFolder
    
End Sub

Sub FindFiles(fsoPFolder As Scripting.Folder)
    Dim fsoFile As Scripting.File
    Dim fsoSFolder As Scripting.Folder
    Dim wkbkW1 As Workbook

    For Each fsoFile In fsoPFolder.Files
        Cells(lngR, "A").Value = fsoPFolder.Path
        Cells(lngR, "B").Value = fsoFile.Name
        lngR = lngR + 1
    Next fsoFile

    For Each fsoSFolder In fsoPFolder.SubFolders
        FindFiles fsoSFolder
    Next fsoSFolder

End Sub

I think it was because you were processing subfolders first and launching a new FSO for each, which meant that your code would go to the deepest folder in the path, and find the files, then step out one level and reprocess it again - so however many folders you had, you would get that many multiples. I had 7 lisitngs for every file, because I had 7 sub folders in my path. But, I think it never fully processed the lowest level of sub-folder, so those files were missing - you needed to move your files loop outside your sub-folder loop:

For Each SubFolder In folder.SubFolders
    Call GetFiles(SubFolder.path)
Next SubFolder   'This is needed here

For Each file In folder.Files
     'Code here
Next file
' Next SubFolder   'And not here