Add unique items in Listbox based on Combobox

Hi,

I have this combobox that is populated by column A.

And a Listbox that was populated based on combobox Vlookup from Column C.

I need to add the unique items in column C to Listbox based on Combobox.

Please see codes below.

Dim c As Range, Variance As String
ListBox1.Clear
With Range("Order_list")
    Set c = .Find(Me.ComboBox1, LookIn:=xlValues)
    If Not c Is Nothing Then
        Variance = c.Address
        Do
            ListBox1.AddItem c.Offset(0, 1)
            Set c = .FindNext(c)
        Loop While Not c Is Nothing And c.Address <> Variance
    End If
End With

Please help.

Thank you.

Try with this, change sheet names

Private Sub ComboBox1_Click()
Dim c As Range, Variance As String
ListBox1.Clear
With Sheets("Blad1").Range("C:C")
    Set c = .Cells.Find(Me.ComboBox1, LookIn:=xlValues)
    If Not c Is Nothing Then
        Variance = c.Address
        Do
            If Application.CountIf(Sheets("blad1").Range("D1", "D" & c.Row), c.Offset(, 1)) = 1 Then
                ListBox1.AddItem c.Offset(0, 1)
            End If
            Set c = .FindNext(c)
        Loop While Not c Is Nothing And c.Address <> Variance
    End If
End With
End Sub

Kind regards
Leo

Try

Dim c As Range, Variance As String, dic As Object
Set dic = CreateOjbect("Scripting.Dictionary")
dic.CompareMode = 1
ListBox1.Clear
With Range("Order_list")
    Set c = .Find(Me.ComboBox1, LookIn:=xlValues)
    If Not c Is Nothing Then
        Variance = c.Address
        Do
            dic(c.Offset(0, 1).Value) = Empty
            Set c = .FindNext(c)
        Loop While c.Address <> Variance
        ListBox1.List = dic.keys
    End If
End With

It works! Thank you LeoTaxi