Join elements in an array and output to a single cell

I came across this once before. NewText is Redimmed as a 2D array (even though the first dimension is 1 to 1, it is still a 2D array), but the Join() function can only operate on 1D arrays. Why are you using NewText as a 2D array? If there is no specific reason for NewText to be 2D, the solution is to Redim NewText as a 1D array

ReDim Preserve NewText(1 to cnt)
NewText(cnt)=Mid(c,i,1)

In addition to the array needing to be 1D instead of 2D, since you are populating the array 1 element at a time, you could skip that and just build the output string:

Sub test()
    Dim NewText As String
    Dim oldtext As Range
    Dim c As Range
    Dim cnt As Long
    Dim i As Long
    
    Set oldtext = Range("C4:C8")
    
    For Each c In oldtext
        NewText = ""
        For i = 1 To Len(c)
            If Asc(Mid(c, i, 1)) > 48 And Asc(Mid(c, i, 1)) <= 57 Then
                If NewText = "" Then
                    NewText = Mid(c, i, 1)
                Else
                    NewText = NewText & "/" & Mid(c, i, 1)
                End If
            End If
        Next i
        
        c(1, 2).Value = NewText
         
    Next c
    
End Sub

I should also have pointed out a possible issue:

If you have 2 or 3 numbers in a cell, the output could be converted to a date - You might want to format the output cells as text prior to running the code or in code prior to entering the values to prevent that.