Live update of .ListBox.Selected

Hello radddogg,

You should use a CommandButton to run the macro. This will also let the user edit the selections before they are applied.

Here is an example where the code has been moved to a command button named "ComanndButton1" on the UserForm.

Private Sub CommandButton1_Click()
    Dim Ndx As Long
    Application.ScreenUpdating = False
    With Me.ListBox1
            If .Selected(0) Then
            ActiveSheet.Columns("L:BM").Hidden = False
        Else
            For Ndx = 1 To .ListCount - 1
                Sheets("Analysis").Columns(Ndx + 11).Hidden = Not .Selected(Ndx)
            Next Ndx
        End If
    End With
    Application.ScreenUpdating = True
End Sub

Hi,

I tend to agree about using a button but purely for information you can use a control variable. Add to the top of the form module

Dim bNoEvents as Boolean

and then amend your code to

Private Sub ListBox1_Change()
    Dim Ndx As Long
    If bNoEvents Then Exit Sub
    Application.ScreenUpdating = False
    With Me.ListBox1
            If .Selected(0) Then
            ActiveSheet.Columns("L:BM").Hidden = False
        Else
            bNoEvents = True
            .Selected(0) = False
            bNoEvents = False
            For Ndx = 1 To .ListCount - 1
                Sheets("Analysis").Columns(Ndx + 11).Hidden = Not .Selected(Ndx)
            Next Ndx
        End If
    End With
    Application.ScreenUpdating = True
End Sub

This deselects all other selections when you select All and deselects All when you select any column.

Private Sub ListBox1_Change()
    Dim Ndx As Long
    Static DisableListBoxEvents As Boolean
    If DisableListBoxEvents = True Then Exit Sub
    DisableListBoxEvents = True
    Application.ScreenUpdating = False
    With Me.ListBox1
        If .ListIndex = 0 And .Selected(0) Then
            ActiveSheet.Columns("L:BM").Hidden = False
            For Ndx = 1 To .ListCount - 1
                .Selected(Ndx) = False
            Next Ndx
        Else
            .Selected(0) = False
            For Ndx = 1 To .ListCount - 1
                Sheets("Analysis").Columns(Ndx + 11).Hidden = Not .Selected(Ndx)
            Next Ndx
        End If
    End With
    DisableListBoxEvents = False
    Application.ScreenUpdating = True
End Sub