Set pivot table value filter with cell value

I am looking to use the number entered in a cell as the "greater than or equal to" value filter for my pivot table values "Order History" and "Percent Difference."

I have two variables: Minimum Order History and Minimum Percent Difference (cells D3 & D4). I would like any entries that do not meet both pieces of criteria to disappear. I have zero VBA knowledge so hoping that someone will be able to assist me!

The workbook is attached and any help is greatly appreciated!

You cannot have more than 1 value filter applied to any given PivotField.

Workaround is to add one of the field to Report Filter.

Also, I need bit of clarification.
Minimum% Difference... you only want positive % Difference >=40%?

Correct...only positive. I can apply a filter when exporting the data for the minimum order history so if it can only be done for percent difference, that is perfectly fine.

Thanks!

Something like below for filtering Percent Difference.

In Standard module.

Sub FilterPercentDiff(fval As Double)
Dim pvt As PivotTable

Set pvt = Worksheets("Sheet3").PivotTables("PivotTable1")
Application.ScreenUpdating = False
With pvt.PivotFields("NAED - Desc")
    .ClearAllFilters
    .PivotFilters.Add2 Type:=xlValueIsGreaterThanOrEqualTo, _
        DataField:=pvt.PivotFields("Percent Difference "), _
        Value1:=fval
End With
Application.ScreenUpdating = True
End Sub

Then in Worksheet module for Sheet3.

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$D$4" Then
    Call FilterPercentDiff(Target.Value)
End If
End Sub

Sample attached.

Thanks so much CK76! I am getting a bug with the following line:

Private Sub Worksheet_Change(ByVal Target As Range)
(1st line for sheet 3)

I have no knowledge of VBA so I don't know what would be used to correct this. Do you have any idea what may be wrong here?

Thanks!

Did you paste in worksheet module?

0.JPG

On another thought made modification which would make it bit more dynamic. It assumes there's only 1 pivot table on the sheet and Field names are same as the sample.

In worksheet module.

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$D$4" Then
    Call FilterPercentDiff(Target.Value, Target.Parent.PivotTables(1))
End If
End Sub

In Standard module.

Sub FilterPercentDiff(fval As Double, pvt As PivotTable)

Application.ScreenUpdating = False
With pvt.PivotFields("NAED - Desc")
    .ClearAllFilters
    .PivotFilters.Add2 Type:=xlValueIsGreaterThanOrEqualTo, _
        DataField:=pvt.PivotFields("Percent Difference "), _
        Value1:=fval
End With
Application.ScreenUpdating = True
End Sub

Thanks again! I followed your instructions but I am receiving the same error with the new code as well. The first screenshot is the initial popup and the second is after pressing OK.

2017-03-09_16-20-10.png

2017-03-09_16-21-41.png

Hmm? That error tells me that you either don't have Sub FilterPercentDiff in the right location or at all.

Make sure that is copied to Module1.

That was my issue. I had the code in ThisWorkbook rather than in Module1. Thanks so much for your help!!!