Format E-mail Body

Hello everyone,

Can someone help me to format my e-mail body to the same as the default format of the e-mails?

I have .htmlbody because the Signature contains an image.

Also, the message is in a worksheet, but now I lost the breaks between lines of the cells.

eg:

Hello,

Regards.

Now is:

Hello, Regards.

Here's the code:

Sub Mail_single()

With Application
        .ScreenUpdating = False
        .Calculation = xlCalculationAutomatic
        .DisplayAlerts = False
        .EnableEvents = False
End With

    'avoid multiple selections
    If Selection.Count = 1 Then
    Else
    Exit Sub
    End If

Dim settings As Worksheet
Dim contacts As String
Dim master As Worksheet

Set settings = ThisWorkbook.Worksheets("settings")
contacts = ActiveSheet.Name
Set master = ThisWorkbook.Worksheets("Claim Master")

Dim nclaims As Variant
Dim disptype As Variant
Dim status As Variant
Dim supplier As Variant
Dim supname As Variant
Dim supcontact As Variant
Dim supmsg As Variant

nclaims = settings.Cells(62, 22)
disptype = settings.Cells(63, 22)
status = settings.Cells(66, 22)
supplier = settings.Cells(67, 22)
supname = settings.Cells(58, 22)
supcontact = settings.Cells(59, 22)
supmsg = settings.Cells(64, 22)

'Only for the suppliers that are to be contacted by e-mail
If Cells(ActiveCell.Row, disptype) <> "Email" Then
MsgBox ("This supplier should be contacted by " & Cells(ActiveCell.Row, disptype))
Exit Sub
Else
End If

If Cells(ActiveCell.Row, nclaims) = 0 Then
MsgBox ("Please select a supplier with pending claims")
Exit Sub
Else
End If

    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object
          
    Dim sup As Range
    Set sup = Cells(ActiveCell.Row, supname)
            
    master.Activate
    Dim Claims As Workbook
    Set Claims = ThisWorkbook
    
'Create a temporary sheet with the filtered data
If ActiveSheet.AutoFilterMode Then
    ActiveSheet.AutoFilter.ShowAllData
    Else
    End If

    Cells(3, 1).Select
    Range(Selection, Selection.End(xlToRight)).Select
    Selection.AutoFilter
              
ActiveSheet.Range(Cells(3, 1), Cells(Cells(1, 1).End(xlDown).Rows, 20)).AutoFilter Field:=status, Criteria1:="Disputed"
ActiveSheet.Range(Cells(3, 1), Cells(Cells(1, 1).End(xlDown).Rows, 20)).AutoFilter Field:=supplier, Criteria1:=sup.Text

Sheets.Add after:=ActiveSheet
ActiveSheet.Name = "Disputed Claims"

Dim LR As Long, LC As Long
LR = master.Cells(1, 1).End(xlDown).Row
LC = master.Cells(3, 1).End(xlToRight).Column

master.Activate
ActiveSheet.Range(Cells(1, 1), Cells(LR, LC)).Copy
Sheets("Disputed Claims").Activate

Cells(1, 1).PasteSpecial xlPasteAll

master.Cells(2, 20).Copy

'Format attachment
Columns(15).ColumnWidth = 28

'Columns(2).Delete
Columns(7).Delete
Columns(9).Delete

Rows(1).Clear
Cells(1, 1) = "Pending Claims"
Cells(1, 1).Font.Size = 18
    
    Columns(1).EntireColumn.AutoFit
    Rows(1).EntireRow.AutoFit
    
    Cells(1, 2) = sup.Value
    Cells(1, 2).Font.Size = 18
    
    Rows(2).Delete
    
    Cells.EntireColumn.AutoFit
    
Cells(1, 1).Select
Application.CutCopyMode = False

'This creates the attachment
Sheets("Disputed Claims").Copy

Set Sourcewb = ActiveWorkbook
    Set Destwb = ActiveWorkbook
     
      'Determine the Excel version, and file extension and format.
    With Destwb
                Select Case Sourcewb.FileFormat
                Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
                Case 52:
                    If .HasVBProject Then
                        FileExtStr = ".xlsm": FileFormatNum = 52
                    Else
                        FileExtStr = ".xlsx": FileFormatNum = 51
                    End If
                End Select
    End With
     
    Dim mysheet As Worksheet, lp As Long
  
    'Save the new workbook/Mail it/Delete it
    TempFilePath = Environ$("temp") & "\"
    TempFileName = "Disputed Claims " & sup.Value & " " & Format(Now, "dd-mmm-yy")

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    
    row_number = sup.Row
    
    Dim mail_mail_body_message As String
    Dim full_name As String
    Dim contact As String
    contact = Claims.Sheets(contacts).Cells(row_number, supcontact)
    mail_body_message = Claims.Sheets(contacts).Cells(row_number, supmsg)
            
    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .display
            .To = contact
            .CC = ""
            .BCC = ""
            .Subject = TempFileName
            .htmlbody = mail_body_message & .htmlbody
            .Attachments.Add Destwb.FullName
            If Claims.Worksheets(contacts).Cells(1, 11).Value = "Yes" Then
            If contact = "" Then
                MsgBox (sup.Value & " does not have assigned any contact")
                .Send
                 Else
                .Send
                End If
            Else
            .display
            End If
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    If ActiveSheet.AutoFilterMode Then
    ActiveSheet.AutoFilter.ShowAllData
    Else
    End If
    
    Application.CutCopyMode = False

master.Activate

    If ActiveSheet.AutoFilterMode Then
    ActiveSheet.AutoFilter.ShowAllData
    Else
    End If

Sheets("Disputed Claims").Delete
      
Sheets(contacts).Activate
    
ActiveSheet.Cells.EntireRow.Hidden = False
    
    With Application
        .ScreenUpdating = True
        .DisplayAlerts = True
        .EnableEvents = True
    End With
    
    If Claims.Worksheets(contacts).Cells(1, 11).Value = "Yes" Then
    MsgBox ("E-mail sent")
    Else
    End If
    
    On Error Resume Next
    OutApp.Show
        
End Sub

Thank you for your help.

Hello, thank you for your reply.

What I mean by default format does not refer to the code. When you create a new e-mail with outlook, you already have a format for the text you are going to write.
I want the cells from the worksheet to be in that format.

Here's the result I have:

Capturar.PNG

And here's what I want:

Capturar1.PNG

Just one thing that will also add difficulty to the case: the message i need to format is not always the same, so the line break will not occur always in the same place.

When I had .body, although i couldn't get the signature, the cells was copied correctly, but now, not only it is pasted as plain text, it also loses the line breaks.

Thank you for your help.

Hi Rui,

To solve your problem, you have to understand the difference between an Outlook Email .Body and .HTMLBody.

When sending an Email using Outlook, the Email Body can be either .Body or .HTMLBody:
a. Body uses ASCII code for a NEW LINE which can be one of:
(1) Carriage Return LineFeed - the combination of Characters Chr(13) and Chr(10) which can also be coded as vbCrLf.
(2) LineFeed Only - Chr(10) which can also be coded as vbLf.
(3) Carriage Return Only - Chr(13) which can also be coded as vbCr.
NOTE: The above numbers are decimal numbers (e.g. the ASCII code for Linefeed is Decimal 10).

b. HTMLBody uses HTML code to indicate a NEW LINE. The HTML Code for NEW LINE is <BR> .

c. To switch between .Body and .HTMLBody, the appropriate NEW LINE code must be used.

For example if reading code from a Cell and to convert to HTML:

'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B12").Value
  
  'Replace ASCII NEW LINE with HTML NEW LINE
  sBody = Replace(sBody, vbCrLf, "<BR>")
  sBody = Replace(sBody, vbLf, "<BR>")
  sBody = Replace(sBody, vbCr, "<BR>")

To convert from HTML code to Body code:

 'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B14").Value
  
  'Replace HTML NEW LINE with  NEW LINE
  sBody = Replace(sBody, "<BR>", vbCr)

See the attached file which demonstrates the above concepts and contains the following code in ordinary code module ModOutlookBodyVsHTMLBody:

Option Explicit

Sub OutlookEmailB12AsBodyAsIs()
  'This assumes that Outlook is already open to simplify the code
  
  Dim OutApp As Object
  Dim OutMail As Object
  
  Dim sBody As String
  
  'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B12").Value
  
  
 'Attempt to create an Outlook object
  On Error Resume Next
  Set OutApp = GetObject(, "Outlook.Application")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "NOTHING DONE.  The Outlook Object could not be created from Excel." & vbCrLf & _
           "Try again when Outlook is open."
    Exit Sub
  End If
  On Error GoTo 0
  
  
  'Create the Outlook Mail Object (using the default Email account)
  Set OutMail = OutApp.CreateItem(0)
 
  'Determine the values to be sent
  With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "Cell B12 as Body (as is)"
    .Body = sBody
     
    .Display
    
    '.Send - comment out the 'Display line' if you want to send
  End With
  
  'Clear the Object Pointers
  Set OutMail = Nothing
  Set OutApp = Nothing

End Sub


Sub OutlookEmailB12AsHTMLBodyAsIs()
  'This assumes that Outlook is already open to simplify the code
  
  Dim OutApp As Object
  Dim OutMail As Object
  
  Dim sBody As String
  
  'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B12").Value
  
  
 'Attempt to create an Outlook object
  On Error Resume Next
  Set OutApp = GetObject(, "Outlook.Application")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "NOTHING DONE.  The Outlook Object could not be created from Excel." & vbCrLf & _
           "Try again when Outlook is open."
    Exit Sub
  End If
  On Error GoTo 0
  
  
  'Create the Outlook Mail Object (using the default Email account)
  Set OutMail = OutApp.CreateItem(0)
 
  'Determine the values to be sent
  With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "Cell B12 as HTMLBody (as is)"
    .HTMLBody = sBody
     
    .Display
    
    '.Send - comment out the 'Display line' if you want to send
  End With
  
  'Clear the Object Pointers
  Set OutMail = Nothing
  Set OutApp = Nothing

End Sub

Sub OutlookEmailB12AsHTMLBodyConverted()
  'This assumes that Outlook is already open to simplify the code
  
  Dim OutApp As Object
  Dim OutMail As Object
  
  Dim sBody As String
  
  'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B12").Value
  
  'Replace ASCII NEW LINE with HTML NEW LINE
  sBody = Replace(sBody, vbCrLf, "<BR>")
  sBody = Replace(sBody, vbLf, "<BR>")
  sBody = Replace(sBody, vbCr, "<BR>")
  
  
 'Attempt to create an Outlook object
  On Error Resume Next
  Set OutApp = GetObject(, "Outlook.Application")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "NOTHING DONE.  The Outlook Object could not be created from Excel." & vbCrLf & _
           "Try again when Outlook is open."
    Exit Sub
  End If
  On Error GoTo 0
  
  
  'Create the Outlook Mail Object (using the default Email account)
  Set OutMail = OutApp.CreateItem(0)
 
  'Determine the values to be sent
  With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "Cell B12 as HTMLBody (Converted To HTML)"
    .HTMLBody = sBody
     
    .Display
    
    '.Send - comment out the 'Display line' if you want to send
  End With
  
  'Clear the Object Pointers
  Set OutMail = Nothing
  Set OutApp = Nothing

End Sub


Sub OutlookEmailB14AsBodyAsIs()
  'This assumes that Outlook is already open to simplify the code
  
  Dim OutApp As Object
  Dim OutMail As Object
  
  Dim sBody As String
  
  'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B14").Value
  
  
 'Attempt to create an Outlook object
  On Error Resume Next
  Set OutApp = GetObject(, "Outlook.Application")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "NOTHING DONE.  The Outlook Object could not be created from Excel." & vbCrLf & _
           "Try again when Outlook is open."
    Exit Sub
  End If
  On Error GoTo 0
  
  
  'Create the Outlook Mail Object (using the default Email account)
  Set OutMail = OutApp.CreateItem(0)
 
  'Determine the values to be sent
  With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "Cell B14 as Body (as is)"
    .Body = sBody
     
    .Display
    
    '.Send - comment out the 'Display line' if you want to send
  End With
  
  'Clear the Object Pointers
  Set OutMail = Nothing
  Set OutApp = Nothing

End Sub


Sub OutlookEmailB14AsHTMLBodyAsIs()
  'This assumes that Outlook is already open to simplify the code
  
  Dim OutApp As Object
  Dim OutMail As Object
  
  Dim sBody As String
  
  'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B14").Value
  
  
 'Attempt to create an Outlook object
  On Error Resume Next
  Set OutApp = GetObject(, "Outlook.Application")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "NOTHING DONE.  The Outlook Object could not be created from Excel." & vbCrLf & _
           "Try again when Outlook is open."
    Exit Sub
  End If
  On Error GoTo 0
  
  
  'Create the Outlook Mail Object (using the default Email account)
  Set OutMail = OutApp.CreateItem(0)
 
  'Determine the values to be sent
  With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "Cell B14 as HTMLBody (as is)"
    .HTMLBody = sBody
     
    .Display
    
    '.Send - comment out the 'Display line' if you want to send
  End With
  
  'Clear the Object Pointers
  Set OutMail = Nothing
  Set OutApp = Nothing

End Sub

Sub OutlookEmailB14AsBodyConverted()
  'This assumes that Outlook is already open to simplify the code
  
  Dim OutApp As Object
  Dim OutMail As Object
  
  Dim sBody As String
  
  'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B14").Value
  
  'Replace HTML NEW LINE with  NEW LINE
  sBody = Replace(sBody, "<BR>", vbCr)
  
  
 'Attempt to create an Outlook object
  On Error Resume Next
  Set OutApp = GetObject(, "Outlook.Application")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "NOTHING DONE.  The Outlook Object could not be created from Excel." & vbCrLf & _
           "Try again when Outlook is open."
    Exit Sub
  End If
  On Error GoTo 0
  
  
  'Create the Outlook Mail Object (using the default Email account)
  Set OutMail = OutApp.CreateItem(0)
 
  'Determine the values to be sent
  With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "Cell B14 as Body (Converted To Body)"
    .Body = sBody
     
    .Display
    
    '.Send - comment out the 'Display line' if you want to send
  End With
  
  'Clear the Object Pointers
  Set OutMail = Nothing
  Set OutApp = Nothing

End Sub

It is a best practice to declare all variables. If you misspell a variable in your code, VBA will silently assume it is a Variant variable and go on executing with no clue to you that you have a bug. Go to the VBA development window, click Tools, Options, and check "Require Variable Declaration." This will insert the following line at the top of all new modules:

Option Explicit

This option requires all variables to be declared and will give a compiler error for undeclared variables.

Lewis

Thank you very much for your explanation.

For the line breaks, the problem is solved (although I will need more time to understand it all, because the ASCII part is completely new to me). I have the cell in my worksheet to read as HTML and it works thanks to you.

The thing is, to have my signature, which contains an image, I need to have .htmlbody, right? But that way, how can i keep the format on the body? Because when I convert to .body, I loose the image from the signature. I've tried to convert to .body and then convert back to .htmlbody but that does not seem to do the trick.

Anyway, thank you for the explanation. Not only you tried to help with the problem, but also provided a way to learn the basis, so I am grateful for your answer.

PS: thank you for the Variable Declaration advice. It's a nice control to have.

To add the signature, try the following (new code in red):

Sub OutlookEmailB12AsHTMLBodyConvertedWithSignature()
  'This assumes that Outlook is already open to simplify the code
  
  Dim OutApp As Object
  Dim OutMail As Object
  
  Dim sBody As String
  
  'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B12").Value
  
  'Replace ASCII NEW LINE with HTML NEW LINE
  sBody = Replace(sBody, vbCrLf, "<BR>")
  sBody = Replace(sBody, vbLf, "<BR>")
  sBody = Replace(sBody, vbCr, "<BR>")
  
  
 'Attempt to create an Outlook object
  On Error Resume Next
  Set OutApp = GetObject(, "Outlook.Application")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "NOTHING DONE.  The Outlook Object could not be created from Excel." & vbCrLf & _
           "Try again when Outlook is open."
    Exit Sub
  End If
  On Error GoTo 0
  
  
  'Create the Outlook Mail Object (using the default Email account)
  Set OutMail = OutApp.CreateItem(0)

  'Grab the Signature
  OutMail.display
 
  'Determine the values to be sent
  With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "Cell B12 as HTMLBody (Converted To HTML)"
    .HTMLBody = sBody & .HTMLBody
     
    .Display
    
    '.Send - comment out the 'Display line' if you want to send
  End With
  
  'Clear the Object Pointers
  Set OutMail = Nothing
  Set OutApp = Nothing

End Sub

Lewis

With the workbook you provided, and with the change you made above, the result is this:

Capturar.PNG

where the bottom part is the logo (image) I have in the signature.

Trying it in the Convert 'B14' to .Body, this is the result:

Capturar1.PNG

Where no logo appears.

So here you can see my dilemma. I either have the body formatted the way I want it but without the Signatures logo, or have the Signature alright but not the body format.

Anyway, thanks again for your efforts.

Rui said:

So here you can see my dilemma. I either have the body formatted the way I want it but without the Signatures logo, or have the Signature alright but not the body format.

In Excel 2016, I was able to duplicate your problem.

Outlook Font Types and Sizes.
(1) My default is Calibri 11 (unchanged from Microsoft default) using Outlook 2016.
(2) Creating Outlook Emails from Excel with the .Body command uses Font Calibri 12.
(3) Creating Outlook Emails from Excel with the .HTMLBody command and no signature uses Font Times New Roman 12.
(4) Creating Outlook Emails from Excel with the .HTMLBody command and signature uses Font Times New Roman 12 for the first paragraph and font Calibri 10 for other paragraphs.

The good news was that I was able to workaround the problem using some HTML code to control the font name and the font size in the body, when a signature was used.

See the attached demo file, which contains the following updated VBA code. Items of interest are in red.

Hard Coded Font Name and Font Size (Module ModOutlookBodyVsHTMLBody):

Sub OutlookEmailB12AsHTMLBodyConvertedAddSignature()
  'This assumes that Outlook is already open to simplify the code
  '
  'The 'Font Name' and 'Font Size' attributes are hard coded in the .HTML line
  
  Dim OutApp As Object
  Dim OutMail As Object
  
  Dim sBody As String
  
  'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B12").Value
  
  'Replace ASCII NEW LINE with HTML NEW LINE
  sBody = Replace(sBody, vbCrLf, "<BR>")
  sBody = Replace(sBody, vbLf, "<BR>")
  sBody = Replace(sBody, vbCr, "<BR>")
  
  
 'Attempt to create an Outlook object
  On Error Resume Next
  Set OutApp = GetObject(, "Outlook.Application")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "NOTHING DONE.  The Outlook Object could not be created from Excel." & vbCrLf & _
           "Try again when Outlook is open."
    Exit Sub
  End If
  On Error GoTo 0
  
  
  'Create the Outlook Mail Object (using the default Email account)
  Set OutMail = OutApp.CreateItem(0)
  
  'Grab the Signature
  OutMail.display
 
  'Determine the values to be sent
  With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "Cell B12 as HTMLBody (Converted To HTML) with Signature - Hard Coded Font Attributes - Calibri 11"
     
    .htmlbody = "<p style='font-family:Calibri; font-size:11pt'>" & sBody & "</p>" & .htmlbody
     
    .display
    
    '.Send - comment out the 'Display line' if you want to send
  End With
  
  'Clear the Object Pointers
  Set OutMail = Nothing
  Set OutApp = Nothing

End Sub

Font Name and Font Size as variables in the code (Module ModZTest):

Sub OutlookEmailB12AsHTMLBodyConvertedAddSignature2()
  'This assumes that Outlook is already open to simplify the code
  '
  'The 'Font Name' and 'Font Size' attributes are variables
  
  Dim OutApp As Object
  Dim OutMail As Object
  
  Dim sBody As String
  Dim sFontName As String
  Dim sFontSize As String
  
  'Set the Font Name and Font Size
  sFontName = "Arial"
  sFontSize = "13"
  
  
  'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B12").Value
  
  'Replace ASCII NEW LINE with HTML NEW LINE
  sBody = Replace(sBody, vbCrLf, "<BR>")
  sBody = Replace(sBody, vbLf, "<BR>")
  sBody = Replace(sBody, vbCr, "<BR>")
  
  
 'Attempt to create an Outlook object
  On Error Resume Next
  Set OutApp = GetObject(, "Outlook.Application")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "NOTHING DONE.  The Outlook Object could not be created from Excel." & vbCrLf & _
           "Try again when Outlook is open."
    Exit Sub
  End If
  On Error GoTo 0
  
  
  'Create the Outlook Mail Object (using the default Email account)
  Set OutMail = OutApp.CreateItem(0)
  
  'Grab the Signature
  OutMail.display
 
  'Determine the values to be sent
  With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "Cell B12 as HTMLBody (Converted To HTML) with Signature - Font Attributes as Variables - Arial 13"
     
    .htmlbody = "<p style='font-family:" & sFontName & ";font-size:" & sFontSize & "pt'>" & sBody & "</p>" & .htmlbody
     
    .display
    
    '.Send - comment out the 'Display line' if you want to send
  End With
  
  'Clear the Object Pointers
  Set OutMail = Nothing
  Set OutApp = Nothing

End Sub

Font Name and Font Size as variables in the code with values obtained from the Spreadsheet (Module ModZTest):

Sub OutlookEmailB12AsHTMLBodyConvertedAddSignature3()
  'This assumes that Outlook is already open to simplify the code
  '
  'The 'Font Name' and 'Font Size' attributes are variables obtained from the Spreadsheet
  
  Dim OutApp As Object
  Dim OutMail As Object
  
  Dim sBody As String
  Dim sFontName As String
  Dim sFontSize As String
  
  'Get the Font Name and Font Size from the Spreadsheet
  sFontName = ThisWorkbook.Sheets("Sheet1").Range("Q16").Value
  sFontSize = ThisWorkbook.Sheets("Sheet1").Range("Q17").Value
  
  
  'Get the Email Body from the cell
  sBody = ActiveSheet.Range("B12").Value
  
  'Replace ASCII NEW LINE with HTML NEW LINE
  sBody = Replace(sBody, vbCrLf, "<BR>")
  sBody = Replace(sBody, vbLf, "<BR>")
  sBody = Replace(sBody, vbCr, "<BR>")
  
  
 'Attempt to create an Outlook object
  On Error Resume Next
  Set OutApp = GetObject(, "Outlook.Application")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "NOTHING DONE.  The Outlook Object could not be created from Excel." & vbCrLf & _
           "Try again when Outlook is open."
    Exit Sub
  End If
  On Error GoTo 0
  
  
  'Create the Outlook Mail Object (using the default Email account)
  Set OutMail = OutApp.CreateItem(0)
  
  'Grab the Signature
  OutMail.display
 
  'Determine the values to be sent
  With OutMail
    .To = ""
    .CC = ""
    .BCC = ""
    .Subject = "Cell B12 as HTMLBody (Converted To HTML) with Signature - Font Attributes Obtained From Spreadsheet"
     
    .htmlbody = "<p style='font-family:" & sFontName & ";font-size:" & sFontSize & "pt'>" & sBody & "</p>" & .htmlbody
     
    .display
    
    '.Send - comment out the 'Display line' if you want to send
  End With
  
  'Clear the Object Pointers
  Set OutMail = Nothing
  Set OutApp = Nothing

End Sub

Lewis

Thank you so much.

I will use the second option you presented. I have multiple users for the code, so I need to keep the format flexible. Since I already have cells prepared to adapt according to each user (I have a userform when the excel opens to indicate the user - so it changes the default paths to linked workbooks), I will simply have to write the default formats.

Once again, thank you very much. Not only did you help to solve the situation, but also provided a way to learn why I was having difficulties.

All the best.