VBA macro to send emails to list of recipients.

Hello,
I am new in excel macros and will appreciate any help will be provided. I have created excel spreadsheet that sends emails to the list of recipients. It works perfectly fine and captures all the cells needed, but for some reason removes graphs and pictures. I do need graphs and gadgets to go with the email as well. I have attached the spreadsheet for the review. In advance thank you for your help.

Thank you so much for the help.
I tried the micro Logit has provided but unfortunately didn't work for my project. This might work if I was sending the same page to all the recipients, with the same info on it. In my situation metrics will be different for each associate and each associate will only receive their own data. In addition data will be large and be changing every day.
Associate A,
Associate B,
Associate C...
Appropriate email addresses in column A

Thanks again

This will send an email with a specific attachment as listed on Sheet 1. You can change the Column references as needed.

Option Explicit

Sub Send_Files()
'Working in Excel 2000-2016
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
    Dim OutApp As Object
    Dim OutMail As Object
    Dim sh As Worksheet
    Dim cell As Range
    Dim FileCell As Range
    Dim rng As Range

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set sh = Sheets("Sheet1")

    Set OutApp = CreateObject("Outlook.Application")

    For Each cell In sh.Columns("B").Cells.SpecialCells(xlCellTypeConstants)

        'Enter the path/file names in the C:Z column in each row
        Set rng = sh.Cells(cell.Row, 1).Range("C1:C10")

        If cell.Value Like "?*@?*.?*" And _
           Application.WorksheetFunction.CountA(rng) > 0 Then
            Set OutMail = OutApp.CreateItem(0)

            With OutMail
                .to = cell.Value
                .Subject = "Testfile"
                .Body = "Hi " & cell.Offset(0, -1).Value

                For Each FileCell In rng.SpecialCells(xlCellTypeConstants)
                    If Trim(FileCell) <> "" Then
                        If Dir(FileCell.Value) <> "" Then
                            .Attachments.Add FileCell.Value
                        End If
                    End If
                Next FileCell

                .Send  'Or use .Display
            End With

            Set OutMail = Nothing
        End If
    Next cell

    Set OutApp = Nothing
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub