Runtime error 13 type mismatch error

Hi all,

I'm getting the runtime error 13 type mismatch error on the following line of code.

The code it relates to is when a cell is changed in H2 (drop down box).

I get this error when i delete cell values from other cells e.g. when deleting data in range AA30:AA32

Private Sub Worksheet_Change(ByVal Target As Range)

  If Target = Range("H2") Then      ' If dropdown box in H2 is changed, apply below the below code to each option

    If InStr(1, Range("H2"), "Scenario A") > 0 Then      
        Call Unhide_rows
        Call Scenario A
      Else
        If InStr(1, Range("H2"), "Scenario B") > 0 Then
        Call Unhide_rows
        Call Legacy
      Else
            If InStr(1, Range("H2"), "Select") > 0 Then
        Call Unhide_rows
      Else
                If InStr(1, Range("H2"), "Scenario C") > 0 Then
        Call Unhide_rows
      Else
                    If InStr(1, Range("H2"), "Scenario D") > 0 Then
        Call Unhide_rows
  
  End If
      End If
        End If
            End If
                End If
                    End If
  
End Sub

If you are deleting multiple cells then you need to specifically check the address of the changed cell(s)

If Target.Address <> "$H$2" Then Exit Sub

If only 1 cell was changed, then no problem, but comparing a range of cells to a single cell will error if more than 1 cell was changed.

Does this work for you?

Private Sub Worksheet_Change(ByVal Target As Range)

    If Target.Address = "$H$2" Then      ' If dropdown box in H2 is changed, apply below the below code to each option
        Select Case Target.Value
            Case "Scenario A"
                Call Unhide_rows
                Call Scenario_A
            Case "Scenario B"
                Call Unhide_rows
                Call Legacy
            Case "Select", "Scenario C", "Scenario D"
                Call Unhide_rows
        End Select
    End If
    
End Sub

You're welcome and thanks for adding rep points.