Need Help in Macros to Copy a row from different WorkBooks to one sheet one after one

Hi,

I need a macro help.

Need Help in Macros to Copy a particular 2nd row from different workbooks. All these workbooks will be in a particular folder. In all workbooks sheet "DATA" is common, from this i need to copy the 2nd row & paste special the value one after one in a active Master Work Book.

There will be a data collected from each employees in a different work books, In all these files "DATA" sheet is common. From these DATA sheet i would like copy & paste special particularly 2nd Row to my master workbook.

Can you please help me in this.

Thanks & Regards,
VK

Try this one, just change red values to your folder path to files and name of sheet in master wokrbook.

Sub CollateReportFromFiles()
'Open all .XLS in specific folder and import data(2007 compatible)
Dim strFileName As String, strPath As String, MyVal As String
Dim wbkOld As Workbook, wbkNew As Workbook, ws As Worksheet
Dim NR As Long

Application.EnableEvents = False
Application.DisplayAlerts = False

Set wbkNew = ThisWorkbook
strPath = "C:\abc\"
strFileName = Dir(strPath & "*.xlsx")
wbkNew.Activate

NR = 1

'Collate data from each file in the designated folder
    Do While Len(strFileName) > 0
        Set wbkOld = Workbooks.Open(strPath & strFileName)
        wbkOld.Worksheets("DATA").Rows(2).Copy
        wbkNew.Sheets("Report").Range("A" & NR).PasteSpecial xlValues
        NR = NR + 1
        strFileName = Dir
        wbkOld.Close False
    Loop

'Cleanup
    ActiveSheet.Columns("A:Z").AutoFit
    Application.DisplayAlerts = True
    Application.EnableEvents = True
End Sub

Thank you kasan. It works perfectly.