New to VBA, need to do Vlookup after a value is entered

Still having trouble with this. I'm getting an error box after i run the code that says 400.

Dim AuctionDate as String
Dim AuctionNum as String
Dim ws1, ws2, ws3 As Worksheet
    Set ws1 = ThisWorkbook.Sheets("Daily")
    Set ws2 = ThisWorkbook.Sheets("Database")
    Set ws3 = ThisWorkbook.Sheets("Data")

AuctionNum = InputBox("Please enter the auction number", "Next Auction Data")
Range("c6").Value = AuctionNum

AuctionDate = Application.WorksheetFunction.VLookup(AuctionNum, ws2.Range("B3:F30"), 2, False)
MsgBox ("value is " & AuctionDate)

I just need to use the inputed value in the input box for a Vlookup function. That's all I'm trying to do.

1. VLookup finds a match in a column and returns a value from a column to the right not the left.

2. In order to use VLookup, the auction numbers must be in the first column of the database, not the second. As it is, you are looking for the auction number string in a column of dates (excel numbers).

3. Your textbox is returning a text string, say "50", while the auction numbers in the database are Excel number values. So, even if the first column were auction numbers, VLookup would fail because "50" is not 50. So, in addition to being the first column, the auction number column must be formatted as text not general. Alternatively, you can convert the textbox value from string to integer before the lookup.

4. To calculate the total cars for an auction# you will have to use Countif()

What Ben said. Try something like this...

Note: format cell C7 with any date format you like.

Sub Run_Button()
    
    Dim RowMatch As Variant      'Row number of the matched Auction Number
    Dim AuctionNum As Integer    'the auction number
    
    'updates the date with todays date
    Range("H2").Value = Date
    
    'prompts the user to enter the auction number then stores it in the variable AuctionNum,
    'the value is then placed in cell c6 of the workbook
    AuctionNum = Application.InputBox("Please enter the auction number", "Next Auction Data", Type:=1)
    If AuctionNum = 0 Then Exit Sub  'User canceled
    Range("C6").Value = AuctionNum
    
    'Match Auction Number and return the row number of 1st match
    RowMatch = Application.Match(AuctionNum, Sheet2.Range("C:C"), False)
    
    If Not IsError(RowMatch) Then   'Test if match was found
        Range("C7").Value = Sheet2.Range("B" & RowMatch).Value 'Return Value from column B of the matched row
        Range("C8").Value = Sheet2.Range("D" & RowMatch).Value 'Return Value from column D of the matched row
        Range("C9").Value = Application.CountIf(Sheet2.Range("C:C"), AuctionNum) 'Count rows that have the auction number
    Else
        MsgBox "No match found for " & AuctionNum, , "Auction Number Not Found"
    End If
    
End Sub