VBA Sentence case with exceptions

Hello,

I am trying to perform sentence case on a cell with some exceptions.

As an example lets say I have a cell that has the text "MARGARINE IS BETTER THAN BUTTER, TRUE OR FALSE".
I would like to run some VBA to change this too "Margarine is better than butter, TRUE or FALSE".
Currently I have this code:

Sub Sentence_Case()

    For Each cell In Selection.Cells
        s = cell.Value
            Start = True
    For i = 1 To Len(s)
        ch = Mid(s, i, 1)
        Select Case ch
        Case "."
            Start = True
        Case "?"
            Start = True
        Case "a" To "z"
    If Start Then ch = UCase(ch): Start = False
        Case "A" To "Z"
    If Start Then Start = False Else ch = LCase(ch)
        End Select
            Mid(s, i, 1) = ch
    Next
        cell.Value = s
    Next
End Sub

This returns "Margarine is better than butter, true or false".

I would like the true and false to stay in CAPS and also be able to add other exemptions as needed.

Thanks in advance

Tony

Sub Sentence_Case()
  Dim s As Variant, ch As Variant, Start As Boolean
  Dim i As Integer, ii As Integer, cell As Range
  Dim ax() As String
  
  ax() = Split("FALSE,TRUE", ",")
  
  For Each cell In Selection.Cells
    s = cell.Value
    Start = True
    For i = 1 To Len(s)
      ch = Mid(s, i, 1)
      Select Case ch
        Case ".", "?"
          Start = True
        Case "a" To "z"
          If Start Then ch = UCase(ch): Start = False
        Case "A" To "Z"
          If Start Then Start = False Else ch = LCase(ch)
      End Select
      Mid(s, i, 1) = ch
    Next
    For ii = 0 To UBound(ax)
      s = Replace(s, ax(ii), ax(ii), Compare:=vbTextCompare)
    Next ii
    cell.Value = s
  Next
End Sub

Kenneth that worked perfectly. Also allows me to exempt as Proper case if needed, brilliant.
Thank you

Kenneth, I hope I am not breaking any rules here but I would like to know in your macro above say instead of TRUE & FALSE you were to use IN & OUT. How would you prevent it from being applies per say to words like DROPOUT or INPUT

Thanks 6StrinJazzer. So can I reference this post or copy the code from here and paste it in a new post?