Selective listing of files in a folder

[Un-Do Re-Do]

The following code lists all files in a selected folder. Is there any way to list only files that contain specific text. In my case I want to only list files with both brackets. From the list below, output is Volume 1 (Section 1) and Volume 3 (S7). Text within brackets maybe of any length.
I would like to keep code in the same format.

Volume 1 (Section 1)
Volume 2 All
Volume 3 (S7)
Volume 4, Section 10
Volume 5 - Section 3

Sub File_Attributes()
    Dim sFolder As FileDialog
    Set sFolder = Application.FileDialog(msoFileDialogFolderPicker)
    If sFolder.Show = -1 Then
    File_Attributes_List_Files sFolder.SelectedItems(1), True
    End If
End Sub

Sub File_Attributes_List_Files(ByVal SourceFolderName As String, ByVal IncludeSubfolders As Boolean)
    Dim FSO As Object
    Dim SourceFolder As Object
    Dim SubFolder As Object
    Dim FileItem As Object
    Dim r As Long
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set SourceFolder = FSO.GetFolder(SourceFolderName)
    r = ActiveCell.Row
    For Each FileItem In SourceFolder.Files
    Rows(r).Insert
    Cells(r, 3).Formula = FileItem.Name
    r = r + 1
    x = SourceFolder.Path
    Next FileItem
    If IncludeSubfolders Then
    For Each SubFolder In SourceFolder.SubFolders
    File_Attributes_List_Files SubFolder.Path, True
    Next SubFolder
    End If
    Set FileItem = Nothing
    Set SourceFolder = Nothing
    Set FSO = Nothing
    ActiveWorkbook.Saved = True
End Sub

[Norie]

Perhaps.

Sub File_Attributes()
Dim sFolder As FileDialog
    Set sFolder = Application.FileDialog(msoFileDialogFolderPicker)
    If sFolder.Show = -1 Then
        File_Attributes_List_Files sFolder.SelectedItems(1), True
    End If
End Sub

Sub File_Attributes_List_Files(ByVal SourceFolderName As String, ByVal IncludeSubfolders As Boolean)
Dim FSO As Object
Dim SourceFolder As Object
Dim SubFolder As Object
Dim FileItem As Object
Dim r As Long

    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set SourceFolder = FSO.GetFolder(SourceFolderName)

    r = ActiveCell.Row

    For Each FileItem In SourceFolder.Files
        If FileItem.Name Like "*(*)*" Then
            Rows(r).Insert
            Cells(r, 3).Formula = FileItem.Name
            r = r + 1
        End If
    Next FileItem

    If IncludeSubfolders Then
        For Each SubFolder In SourceFolder.SubFolders
            File_Attributes_List_Files SubFolder.Path, True
        Next SubFolder
    End If

    Set FileItem = Nothing
    Set SourceFolder = Nothing
    Set FSO = Nothing
    ActiveWorkbook.Saved = True

End Sub

[Un-Do Re-Do]

If I replace with square brackets, it does not work. Do you know why?

        If FileItem.Name Like "*[*]*" Then

[Un-Do Re-Do]

It seems to work.
Thanks for the modification.

[Un-Do Re-Do]

Thank you again.

[Norie]

When using the Like operator anything between square brackets is treated as a character list to match a single character.

For example if you wanted to check for A-Z you would use [A-Z].

Try this for finding [ followed by ].

Sub File_Attributes()
Dim sFolder As FileDialog
    Set sFolder = Application.FileDialog(msoFileDialogFolderPicker)
    If sFolder.Show = -1 Then
        File_Attributes_List_Files sFolder.SelectedItems(1), True
    End If
End Sub

Sub File_Attributes_List_Files(ByVal SourceFolderName As String, ByVal IncludeSubfolders As Boolean)
Dim FSO As Object
Dim SourceFolder As Object
Dim SubFolder As Object
Dim FileItem As Object
Dim r As Long
Dim pos1 As Long
Dim pos2 As Long

    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set SourceFolder = FSO.GetFolder(SourceFolderName)

    r = ActiveCell.Row

    For Each FileItem In SourceFolder.Files
    
        pos1 = InStr(FileItem.Name, "[")

        If pos1 > 0 Then

            pos2 = InStr(FileItem.Name, "]")

            If pos2 > pos1 Then
                Rows(r).Insert
                Cells(r, 3).Formula = FileItem.Name
                r = r + 1
            End If
            
        End If
        
    Next FileItem

    If IncludeSubfolders Then
        For Each SubFolder In SourceFolder.SubFolders
            File_Attributes_List_Files SubFolder.Path, True
        Next SubFolder
    End If

    Set FileItem = Nothing
    Set SourceFolder = Nothing
    Set FSO = Nothing
    ActiveWorkbook.Saved = True

End Sub