I need VBA code to make each combobox option on a userform open an excel workbook ...

Hi ... I'm new to VBA Coding but I am trying to get a userform with a combobox to open different excel workbooks when an item is selected and the command button is clicked.
The options on the combobox are as follows ...

QTR1 to open "Workbook A"
QTR2 to open "Workbook B"
QTR3 to open "Workbook C"
QTR4 to open "Workbook D"
Daily Audits Completed QTR1 to open "Workbook E"
Daily Audits Completed QTR2 to open "Workbook F"
Daily Audits Completed QTR3 to open "Workbook G"
Daily Audits Completed QTR4 to open "Workbook H"

I hope someone out there can help.

Many thanks in anticipation ....

I suggest that you add an "Open" button rather than opening the file as soon as the user makes a selection. Users can make mistakes. This is the code for the OK button. You put this code in the module for the userform. I have compiled but not tested this, as I would have to create the form and all these files:

Private Sub CommandButton1_Click()

   Select Case Me.ComboBox1
      Case "QTR1"
         Workbooks.Open Filename:="Workbook A"
      Case "QTR2"
         Workbooks.Open Filename:="Workbook B"
      Case "QTR3"
         Workbooks.Open Filename:="Workbook C"
      Case "QTR4"
         Workbooks.Open Filename:="Workbook D"
      Case "Daily Audits Completed QTR1"
         Workbooks.Open Filename:="Workbook E"
      Case "Daily Audits Completed QTR2"
         Workbooks.Open Filename:="Workbook F"
      Case "Daily Audits Completed QTR3"
         Workbooks.Open Filename:="Workbook G"
      Case "Daily Audits Completed QTR4"
         Workbooks.Open Filename:="Workbook H"
   End Select
   
End Sub

Many Thanks ....

It sort of works.
When I click on the command button it opens up the new workbook and closes the userform on the original workbook and leaves that workbook open (which is what I want) but the new workbook is unresponsive (inactive) when it opens.

How do I make the new workbook active when it opens? ...

Edit: ** I've just noticed that when the new workbook opens as unresponsive (inactive), if I click back onto the original workbook with the userform, then click back onto the new workbook it becomes responsive (active) **

Inactive and unresponsive mean two completely different things. Do you mean that the file opens but does not have focus? Or do you mean that the file opens but does not respond to any user input?

I have not tested this but this form of the command may solve it:

Formula:

 Workbooks.Open(Filename:="Workbook A").Activate

If you continue to have problems I will try to set up a test.

I appreciate your time and effort but that didn't work.

I have "Workbook 1" which has a userform (combobox) on it. The userform opens other "Workbooks A to H" depending on what is selected in the userform and after open file is clicked.

By unresponsive I mean that when the new "Workbook A" initially opens, no items on the menu bar work (File, Home, Insert, Page Layout, etc).
But if I click back onto the original "Workbook 1" with the userform the menu items on that workbook work OK...
I then click back onto the new "Workbook A" again and the menu items now work Ok as well.

I've tried it with Unload Me in the code and without Unload Me in the code but that makes no difference.

I hope I've explained my problem clearly now.
I've pasted the code I have so far below ...



Private Sub cbFiles_Change()

Image1.Picture = LoadPicture(ThisWorkbook.Path & "\" & cbFiles.Value & ".jpg")

End Sub

Private Sub cmdOpen_Click()

If cbFiles.Value = "" Then
If MsgBox("You have not selected anything yet. If you continue this selection box will close. Do you want to continue?", vbQuestion + vbYesNo) <> vbYes Then
Exit Sub
End If
End If

Select Case Me.cbFiles
Case "QTR1"
Workbooks.Open(Filename:="C:\Users\Paul\Documents\Workbook A.xlsx").Activate
Case "QTR2"
Workbooks.Open(Filename:="C:\Users\Paul\Documents\Workbook B.xlsx").Activate
Case "QTR3"
Workbooks.Open(Filename:="C:\Users\Paul\Documents\Workbook C.xlsx").Activate
Case "QTR4"
Workbooks.Open(Filename:="C:\Users\Paul\Documents\Workbook D.xlsx").Activate
Case "Daily Audits Completed QTR1"
Workbooks.Open(Filename:="C:\Users\Paul\Documents\Workbook E.xlsx").Activate
Case "Daily Audits Completed QTR2"
Workbooks.Open(Filename:="C:\Users\Paul\Documents\Workbook F.xlsx").Activate
Case "Daily Audits Completed QTR3"
Workbooks.Open(Filename:="C:\Users\Paul\Documents\Workbook G.xlsx").Activate
Case "Daily Audits Completed QTR4"
Workbooks.Open(Filename:="C:\Users\Paul\Documents\Workbook H.xlsx").Activate
End Select

Unload Me

End Sub

Private Sub cmdClose_Click()

Unload Me

End Sub

Try putting Unload Me before the code that opens the workbook(s).

PS Can you add code tags when posting code?

In the code in post #7 the Unload Me is still after the code to open the workbook(s).

This is what I meant.

Private Sub cmdOpen_Click()
Dim strFileName As String

    If cbFiles.Value = "" Then
        If MsgBox("You have not selected anything yet. If you continue this selection box will close. Do you want to continue?", vbQuestion + vbYesNo) <> vbYes Then
            Exit Sub
        End If
    End If

    Unload Me

    Select Case Me.cbFiles
        Case "QTR1"
            strFileName = "Workbook A.xlsx"
        Case "QTR2"
            strFileName = "Workbook B.xlsx"
        Case "QTR3"
            strFileName = "Workbook C.xlsx"
        Case "QTR4"
            strFileName = "Workbook D.xlsx"
        Case "Daily Audits Completed QTR1"
            strFileName = "Workbook E.xlsx"
        Case "Daily Audits Completed QTR2"
            strFileName = "Workbook F.xlsx"
        Case "Daily Audits Completed QTR3"
            strFileName = "Workbook G.xlsx"
        Case "Daily Audits Completed QTR4"
            strFileName = "Workbook H.xlsx"
    End Select

    If strFileName <> "" Then
        Workbooks.Open Filename:="C:\Users\Paul\Documents\" & strFileName
    End If

End Sub