Select Case Problem

Hey everyone, hopefully someone can save the rest of my hair here.

I am trying to loop through 6 specific sheets and adjust their zoom level for displaying on a conference room TV. The code below works for the first 3 sheets wonderfully, but then errors out. If you step through it one line at a time, you can watch as it simply skips the last 3 sheets, as if they've already been done. The sheet names are definitely spelled correctly (copied directly from the tabs to be sure). I can't imagine what the heck I'm doing wrong. For now I'm just selecting each sheet individually and adjusting, but I am always trying to make my code more efficient wherever I can.

Thanks in advance!

Private Sub CommandButton3_Click()
Dim ws As Worksheet, lngZoom As Long
 
For Each ws In ThisWorkbook.Worksheets
     
    Select Case ws.Name
         
    Case "SIP Review": lngZoom = 250
    Case "MOR Dashboard": lngZoom = 200
    Case "Support Tickets": lngZoom = 210
    Case "Overall Score": lngZoom = 260
    Case "Outliers v1": lngZoom = 280
    Case "Outliers v2": lngZoom = 290
         
    End Select
    Application.ScreenUpdating = False
    With ws
        .Select
        ActiveWindow.Zoom = lngZoom
    End With
Next ws
 
Application.ScreenUpdating = True
End Sub

can you upload a workbook? Any chance that last three sheets are actually chart sheets?

What's the error description?
What line is highlighted when you click the debug button on the error dialog?
Are any sheets hidden or protected?

Originally Posted by outofahat

There are hidden sheets, but not any of the ones I am trying to select/zoom.

The .Select is after the Case code block. So it will try to .Select every sheet (including hidden sheets) regardless if it was a sheet within the Case code block.

Try this...

Sub excelforum_test()
Dim ws As Worksheet, lngZoom As Long
Application.ScreenUpdating = False
For Each ws In ThisWorkbook.Worksheets
     
    Select Case ws.Name
         
    Case "SIP Review": lngZoom = 250
    Case "MOR Dashboard": lngZoom = 200
    Case "Support Tickets": lngZoom = 210
    Case "Overall Score": lngZoom = 260
    Case "Outliers v1": lngZoom = 280
    Case "Outliers v2": lngZoom = 290
    Case Else: lngZoom = 0
    End Select
    
    If lngZoom > 0 Then
        With ws
            .Select
            ActiveWindow.Zoom = lngZoom
        End With
    End If
Next ws
Application.ScreenUpdating = True
End Sub

You may want to initialize lgnzoom to 100 to handle any other worksheet cases.

or have a CASE ELSE that sets lgnzoom to 100.