Get Value In Between Strings From All Text Files In Folder

[exc4libur]

Hello!
How are we today? Fine I hope.

I am trying to go through all text files inside a folder and extract the value found in between strings to my worksheet.
The strings to look for are in columns, the beginning string to look for in row 1 and the ending string in row 2.
Please find attached a sample workbook and text file. Also, I have pasted the code of what I have so far.

Thanks in advance for taking the time and trying help

Sub ExtractValueInBetween()
    Dim filename As String, nextrow As Long, MyFolder As String
    Dim MyFile As String, text As String, textline As String, beginStr As String, endStr As String
    
    MyFolder = "C:\test\" 'I need to make this work as a FileDialog Picker!!
    MyFile = Dir(MyFolder & "*.txt")

    Do While MyFile <> ""
        Open (MyFolder & MyFile) For Input As #1
        Do Until EOF(1)
            Line Input #1, textline
            text = text & textline
        Loop
        Close #1
        MyFile = Dir()
        Debug.Print text
        beginStr = InStr(text, Range("b1").Value)
        endStr = InStr(text, Range("b2").Value)
        nextrow = ActiveSheet.Cells(Rows.Count, "B").End(xlUp).Row + 1
        ActiveSheet.Cells(nextrow, "b").Value = Mid(text, beginStr, endStr - beginStr)
        text = ""
    Loop
End Sub

[AlphaFrog]

Sub ExtractValueInBetween()
    Dim filename As String, nextrow As Long, MyFolder As String, c As Long
    Dim MyFile As String, text As String, textline As String, beginStr As String, endStr As String
    
    MyFolder = "C:\test\" 'I need to make this work as a FileDialog Picker!!
    MyFile = Dir(MyFolder & "avar*.txt")
    
    Do While MyFile <> ""
        Open (MyFolder & MyFile) For Input As #1
        Do Until EOF(1)
            Line Input #1, textline
            text = text & textline
        Loop
        Close #1
        MyFile = Dir()
        Debug.Print text
        nextrow = ActiveSheet.Cells(Rows.Count, "B").End(xlUp).Row + 1
        For c = 2 To ActiveSheet.Cells(1, Columns.Count).End(xlToLeft).Column
            beginStr = InStr(text, Cells(1, c).Value) + Len(Cells(1, c).Value)
            endStr = InStr(text, Cells(2, c).Value)
            ActiveSheet.Cells(nextrow, c).Value = Mid(text, beginStr, endStr - beginStr)
        Next c
        text = ""
    Loop
End Sub

[exc4libur]

Genius!!!!!!!!!!!!!!!!!!!!!!!!! YES!!!!!!!!!
Could you add just one quick thing, the filename on column A please!
Thank you sooo much!!

[AlphaFrog]

You're welcome.

Sub ExtractValueInBetween()
    Dim filename As String, nextrow As Long, MyFolder As String, c As Long
    Dim MyFile As String, text As String, textline As String, beginStr As String, endStr As String
    
    MyFolder = "C:\test\" 'I need to make this work as a FileDialog Picker!!
    MyFile = Dir(MyFolder & "*.txt")
    
    Do While MyFile <> ""
        Open (MyFolder & MyFile) For Input As #1
        Do Until EOF(1)
            Line Input #1, textline
            text = text & textline
        Loop
        Close #1
                
        Debug.Print text
        nextrow = ActiveSheet.Cells(Rows.Count, "B").End(xlUp).Row + 1
        ActiveSheet.Cells(nextrow, 1).Value = MyFile
        For c = 2 To ActiveSheet.Cells(1, Columns.Count).End(xlToLeft).Column
            beginStr = InStr(text, Cells(1, c).Value) + Len(Cells(1, c).Value)
            endStr = InStr(text, Cells(2, c).Value)
            ActiveSheet.Cells(nextrow, c).Value = Mid(text, beginStr, endStr - beginStr)
        Next c
        MyFile = Dir
        text = ""
    Loop
End Sub

[exc4libur]

I couldn't thank you enough. Once again, thank you! It was killing me.