Speedup VBA and Apply to all visible sheets

You've got a lot of Select and Activate going on, especially at the beginning of your code....

 Range("F:H,J:L,N:P,R:T").Select
    Range("R1").Activate
    Range("F:H,J:L,N:P,R:T,V:X,Z:AB,AD:AF,AH:AJ").Select
    Range("AH1").Activate
    Range("F:H,J:L,N:P,R:T,V:X,Z:AB,AD:AF,AH:AJ,AL:AN,AP:AR,AT:AV,AX:AZ,BB:BD"). _
        Select
    Range("BB1").Activate
    Range( _
        "F:H,J:L,N:P,R:T,V:X,Z:AB,AD:AF,AH:AJ,AL:AN,AP:AR,AT:AV,AX:AZ,BB:BD,BH:BS"). _
        Select
    Range("BH1").Activate

You are selecting a "range" of columns, then activating a specific cell, then selecting another range of columns and activating another specific cell. Looks to me as if all that is unnecessary.
To speed it up, try this...

Sub RunMetoClean()

Application.DisplayAlerts = False
Application.EnableEvents = False
Application.ScreenUpdating = False

    
    Range("BH1").Delete Shift:=xlToLeft
    Columns("A:A").Delete Shift:=xlToLeft
    Range("E12").Select
    
'    Application.Run "modPaste.Copy"
 Columns("B:B").Copy
    Columns("C:C").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    With Selection.Font
        .Color = -16776961
        .TintAndShade = 0
    End With
    Columns("B:B").Select
    With Selection.Font
        .ThemeColor = xlThemeColorDark1
        .TintAndShade = 0
    End With
    Range("E12").Select
    
     
    Range("A11").Delete Shift:=xlUp
    Rows("1:4").Select
    Selection.Insert Shift:=xlDown
    Range("C8").Select
    ActiveWindow.SmallScroll Down:=-9
    
    Application.DisplayAlerts = True
    Application.EnableEvents = True
    Application.ScreenUpdating = True

End Sub

Originally Posted by gmr4evr1

You are selecting a "range" of columns, then activating a specific cell, then selecting another range of columns and activating another specific cell. Looks to me as if all that is unnecessary.

   Range("BH1").Delete Shift:=xlToLeft
    Columns("A:A").Delete Shift:=xlToLeft
    Range("E12").Select

@gmr4evr1, I think you are misunderstanding what the macro recorder produces.
If you turn on the recorder then hold down Ctrl and select a few columns (say for instance A,D,F) then you will find that it produces an Activate line which is the first cell of the last column selected (in the case of A,D,F it would produce the below code).
The Column is still selected.

Sub Macro1()
    Range("A:A,D:D,F:F").Select
    Range("F1").Activate
End Sub

Totally untested (so test on a copy of your workbook)...

Sub RunMetoClean()
    Dim sht As Worksheet
    Application.DisplayAlerts = False
    Application.EnableEvents = False
    Application.ScreenUpdating = False

    For Each sht In ActiveWorkbook.Worksheets
        If sht.Visible = True Then

            With sht
                .Range( _
                        "F:H,J:L,N:P,R:T,V:X,Z:AB,AD:AF,AH:AJ,AL:AN,AP:AR,AT:AV,AX:AZ,BB:BD,BH:BS").Delete Shift:=xlToLeft
                .Columns("A:A").Delete Shift:=xlToLeft
                .Columns("B:B").Copy

                With .Columns("C:C")
                    .PasteSpecial Paste:=xlPasteValues
                    With .Font
                        .Color = -16776961
                        .TintAndShade = 0
                    End With
                End With

                With .Columns("B:B")
                    With .Font
                        .ThemeColor = xlThemeColorDark1
                        .TintAndShade = 0
                    End With
                End With

                .Rows("1:11").Delete Shift:=xlUp
                .Rows("1:4").Insert Shift:=xlDown
            End With
        End If
    Next
    Application.DisplayAlerts = True
    Application.EnableEvents = True
    Application.ScreenUpdating = True

End Sub

Ok, now I understand that part of it, but, isn't the selecting/activating unnecessary?

Still totally unnecessary (I didn't use it either and I ignored the C8 and scroll at the end because it just looks like the OP was scanning the sheet before they turned off the recorder but I might be wrong).
The OP needed the entire columns deleted rather than a cell and I could see where you were getting it from so I thought it might be of some use to explain what I could see.

Gotcha...thanks for the info.

Not my code but unmerge your cells (and do a Google on Centre across selection).
I also don't see how your original code worked if you have merged cells.