Highlight rows multiple criteria vba

Hello,

Looking for a code that highlights rows when criteria are met (or not) via a InputBox.

e.g.: run macro, input box 1: enter premium, input box 2: enter selected. Run throw the rows and every row that has "premium" and "selected" higlights green, but if there is only 1 of the criteria in the row, highlight red.

Attached is sample of the expected result.


I tried changing the following code as it highlights cells but no luck.

Sub HighlightValue()
'PURPOSE: Highlight all cells containing a specified values
Dim fnd As String, FirstFound As String
Dim FoundCell As Range, rng As Range
Dim myRange As Range, LastCell As Range
'What value do you want to find?
  fnd = InputBox("First Value", "Find", "enter text")
     'End Macro if Cancel Button is Clicked or no Text is Entered
      If fnd = vbNullString Then Exit Sub
Set myRange = ActiveSheet.UsedRange
Set LastCell = myRange.Cells(myRange.Cells.Count)
Set FoundCell = myRange.Find(what:=fnd, after:=LastCell)
'Test to see if anything was found
  If Not FoundCell Is Nothing Then
    FirstFound = FoundCell.Address
  Else
    GoTo NothingFound
  End If
Set rng = FoundCell
'Loop until cycled through all unique finds
  Do Until FoundCell Is Nothing
    'Find next cell with fnd value
      Set FoundCell = myRange.FindNext(after:=FoundCell)
    'Add found cell to rng range variable
      Set rng = Union(rng, FoundCell)
    'Test to see if cycled through to first found cell
      If FoundCell.Address = FirstFound Then Exit Do
  Loop
'Highlight Found cells yellow
  rng.Interior.Color = RGB(255, 255, 0)
'Report Out Message
  MsgBox rng.Cells.Count & " cell(s) were found containing: " & fnd
Exit Sub
'Error Handler
NothingFound:
  MsgBox "No cells containing:"
End Sub

Any help appreciated.

Red

Another:

Sub realrookiezz()
Dim x As Range, y As Range, i As Long, crit1 As String, crit2 As String
crit1 = InputBox("Please Enter Criteria 1")
crit2 = InputBox("Please Enter Criteria 2")
For i = Range("A" & Rows.Count).End(3).row To 2 Step -1
    Set x = Rows(i).Find(crit1, LookIn:=xlValues, lookat:=xlPart)
    Set y = Rows(i).Find(crit2, LookIn:=xlValues, lookat:=xlPart)
    If x Is Nothing And y Is Nothing Then
        GoTo zz
    ElseIf Not x Is Nothing And Not y Is Nothing Then
        Rows(i).Interior.ColorIndex = 4
    Else
        Rows(i).Interior.ColorIndex = 3
    End If
zz:
Next i
End Sub

Mr Davis,

Wonderful as always. But this runs to good. It does what I ask, but when I added it to the live data, i got more results then I expected. Live data has around 28k rows of products and up to Column AP.

Is there a way, so that I can tell it in which column to search first for Criteria 1, and based on those results it would search the rest of the row (where criteria 1 was found) for criteria 2.