Open files that have a variable date format in the name

[MiloDjukanovic]

Macros (attached) task is to open today's file from a folder, copy its contents in Excel sheet and close it.
The files are saved by the application with a strange criteria. Random saves files in formats "d.m.yyyy" or "d.mm.yyyy" or "dd.m.yyyy" or "dd.mm.yyyy" (like "7.5.2016-K.xml" or "7.05.2016-K.xml" or "07.5.2016-K.xml" or "07.05.2016-K.xml"), and I can not affect it.
The macro works perfectly until a date is in ONE of the format above.
Is there a possibility to declare "myToday = Format(Date, "dd.m.yyyy")" with multiple criteria which will include all date formats above, so the macro identifies the file regardless of the date format.

Thanks

Sub CpyCntnt()
Dim strLine As String
Dim i As Integer
Dim myToday As String
Dim strFileName As String

myToday = Format(Date, "dd.m.yyyy")
strFileName = myToday & "-K" & ".xml"
Open "C:\Archive\" & strFileName For Input As #1
i = 1
While EOF(1) = False
    'read the next line of data in the text file
    Line Input #1, strLine
    'print the data in the current row
    Cells(i, 1) = strLine
    'increment the row counter
    i = i + 1
Wend
Close #1
End Sub

[JBeaucaire]

Something like this:

Option Explicit

Sub CpyCntnt()
Dim strLine As String, strFileName As String, i As Long

strFileName = Dir("C:\Archive\" & Format(Date, "dd.m.yyyy") & "-K" & ".xml")
If strFileName = "" Then strFileName = Dir("C:\Archive\" & Format(Date, "d.mm.yyyy") & "-K" & ".xml")
If strFileName = "" Then strFileName = Dir("C:\Archive\" & Format(Date, "dd.mm.yyyy") & "-K" & ".xml")
If strFileName = "" Then
    MsgBox "Dated file not found in tested formats, new one may be in use."
    Exit Sub
End If

Open "C:\Archive\" & strFileName For Input As #1
i = 1
While EOF(1) = False
    Line Input #1, strLine  'read the next line of data in the text file
    Cells(i, 1) = strLine   'print the data in the current row
    i = i + 1               'increment the row counter
Wend
Close #1

End Sub

[MiloDjukanovic]

You are wrong, not "Something like this", just this.

Thanks so much