When clicking cell within range, make it bold. If already bold, make it not bold

Hi there,

Try entering the following code in the VBA CodeModule of the worksheet for which you wish to provide this feature, and see if it does what you need:

Option Explicit


Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Const sTARGET_RANGE As String = "E10:F20"

    Dim iNoOfCells      As Integer

    On Error Resume Next
        iNoOfCells = Target.Cells.Count
    On Error GoTo 0

    If iNoOfCells = 1 Then

        If Not Intersect(Target, _
                         Me.Range(sTARGET_RANGE)) Is Nothing Then

            Target.Font.Bold = Not Target.Font.Bold

        End If

    End If

End Sub

The highlighted value may be altered to suit your own requirements.


Hope this helps - please let me know how you get on.

Regards,

Greg M

It works good, thank you.

But how do I do if I want a macro button that (when clicked) switches selected cell between bold and blue vs not bold not blue within same range E10:F20?

Hi again,

See if the following code does what you need:

Public Sub ToggleCell()

    Const sTARGET_RANGE As String = "E10:F20"
    Const lDARK_BLUE    As Long = &HFF0000
    Const lBLACK        As Long = 0

    Dim rCell           As Range

    For Each rCell In Selection.Cells

        With rCell

            If Not Intersect(rCell, _
                             ActiveSheet.Range(sTARGET_RANGE)) Is Nothing Then

                If .Font.Bold = True Then

                      .Font.Bold = False
                      .Font.Color = lBLACK

                Else: .Font.Bold = True
                      .Font.Color = lDARK_BLUE

                End If

            End If

        End With
        
    Next rCell

End Sub

Select one or more cells and then run the macro to toggle the appearance of the cells.


Hope this helps - please let me know how you get on.

Regards,

Greg M

Greg, it's perfect!
Thank you!

Hi again,

Many thanks for your feedback and also for the Reputation increase - much appreciated

You're welcome - glad I was able to help.

Best regards,

Greg M