Macro to auto update links to password protected workbooks

The files are all in the same directory.
I created a new workbook called "List.xlsX" that contains the path and passwords.

So this is the macro that I am working with.
I am able to have the macro open all of the password protected files.
The current issue I am having is I can get the macro to either not close any of the workbooks when it is done, or it will close all of the workbooks, except for the "list" workbook with the passwords.

In an ideal world, I could move the list workbook to a sheet in my summary workbook, but I can't figure out how to have the macro refer to that sheet specifically. If I was able to do that, the Workbooks(i).Close SaveChanges:=False would, I think close all of the daughter books. Currently, it closes everything but "list".

HTML Code: 

You can see all of the attempts I have made to get this to work commented out.
Am I on the right track at all?

Thanks again,
Mark

Hi Mark,

Here is your code modified so it gets the workbook names and passwords from the List.xlsx file and then opens and closes each password protected workbook. Instead of keeping the "List.xlsx" file open and reading from it while opening each workbook, the code below opens "List.xlsx", populates arrays for the workbook names and passwords, closes "List.xlsx" and then runs through another loop to deal with the password protected workbooks.

Sub updateme()

    Dim myFileNames() As String
    Dim myPasswords() As String
    Dim myRealWkbkName As String
    Dim LastRowA1 As Long
    Dim LastRowB1 As Long
    Dim PWWorkbook As Workbook
    Dim SourceWorkbook As Workbook
    Dim WorkbookPath As String
    Dim i As Integer
    Dim LastRow As Long
    Dim LastColumn As Long
    Dim rng As Range
    
    ' Turn OFF events
    Application.ScreenUpdating = False
    
    WorkbookPath = "C:\!!!!Users\wfh309\Desktop\New Log Setup\January 2016\Case Review Logs\"
    myRealWkbkName = WorkbookPath & "List.xlsx"
   
    ' Open List.xlsx and retrieve reference workbook names and passwords
    Workbooks.Open myRealWkbkName, UpdateLinks:=False
    Set PWWorkbook = ActiveWorkbook
    
    ' Verify list of workbook names is same length as list of corresponding passwords
    LastRowA1 = PWWorkbook.Sheets("List").[A1].End(xlDown).Row
    LastRowB1 = PWWorkbook.Sheets("List").[B1].End(xlDown).Row
    
     If LastRowA1 <> LastRowB1 Then
        MsgBox "check names & passwords--qty mismatch!"
        Exit Sub
     End If
    
    ' Populate wkbName() and wkbPass() arrays from List.xlsx
    ReDim myFileNames(1 To LastRowA1) As String
    ReDim myPasswords(1 To LastRowA1) As String
    For i = 1 To LastRowA1
        myFileNames(i) = PWWorkbook.Sheets(1).Cells(i, 1).Value
        myPasswords(i) = PWWorkbook.Sheets(1).Cells(i, 2).Value
    Next i
    PWWorkbook.Close False
        
    ' Open Password Protected Workbooks, Execute code and close workbook
    For i = 1 To LastRowA1
        Workbooks.Open WorkbookPath & myFileNames(i), UpdateLinks:=False, Password:=myPasswords(i)
        ' < CODE HERE >
        Workbooks(myFileNames(i)).Close SaveChanges:=False
    Next i

    ' Turn ON events
    Application.ScreenUpdating = True
    
End Sub

Hope that helps,

Dan