Sort selected userform listbox items alphabetically

I found a code that sorts a userform listbox alphabetically.
Was wondering if there is a way to first sort all the selections alphabetically witht he first selections at be displayed at the top of the list box and then all the unselected items (already in alphabetical order) to be displed below all the selections?

I know i'm way off but i tried the best i could, see below:

Dim i As Long
Dim j As Long
Dim temp As Variant
   
With Me.BrandListBox
    For j = 0 To BrandListBox.ListCount - 2
        For i = 0 To BrandListBox.ListCount - 2
        If .Selected(i) = True Then
            If .List(i) > .List(i + 1) Then
                temp = .List(i)
                .List(i) = .List(i + 1)
                .List(i + 1) = temp
            End If
        End If
        Next i
    Next j
End With

I really would appreciate any help on this.

i was thinking that maybe the code can achieve the same goal by removing the selected item from the list box and then adding it to the top of the list box like this:

remove:

BrandListBox.RemoveItem BItem

add:

BrandListBox.AddItem BItem, 0

as the "0" adds the item to the top of the list.
One of the problems i am having is that "Bitem" is not a string but rather a number. And the other problem is...i have no clue what i am doing
Once again i am seeking some guidance.

Maybe something like this:
1. assign selected item value to a variable (k)
2. change selected item value to 0 (so it will be on top when sorted)
3. sorting
4. change listindex(0) value to k

Dim i As Long
Dim j As Long, k
Dim temp As Variant
   
With Me.ListBox1
   If .ListIndex <> -1 Then
   k = .Value
   .List(.ListIndex) = 0
   Else
   Exit Sub
   End If
    
    For j = 0 To ListBox1.ListCount - 2
        For i = 0 To ListBox1.ListCount - 2
            If .List(i) > .List(i + 1) Then
                temp = .List(i)
                .List(i) = .List(i + 1)
                .List(i + 1) = temp
            End If

        Next i
    Next j
    .List(0) = k
End With

I made an example regarding how to sort listbox with multi select options.
I use 'System.Collections.ArrayList' object to populate the list because this object has 'built in' sort function.
This is how it work:
1. user pick an item in combobox. It will sort the listbox and clear selection.
2. user pick some item in listbox
3. hit the command button
4. the selected item will be on top & the list below it is sorted.

Private Sub ComboBox1_Change()
Dim dar As Object, r As Range

Set dar = CreateObject("System.Collections.ArrayList")
For Each r In Range("A2", Cells(Rows.Count, "A").End(xlUp))
dar.Add r.Value
Next
dar.Sort
ListBox1.List = dar.toarray()
End Sub



Private Sub CommandButton1_Click()
Dim dar As Object, i As Long
Set dar = CreateObject("System.Collections.ArrayList")
With ListBox1
    'get selected item to dar
    For i = 0 To .ListCount - 1
        If .Selected(i) = True Then
        dar.Add .List(i)
        .List(i) = 0 'selected item become 0
        End If
    Next i
    
    'get listbox list to dar1 and the sorted
    Set dar1 = CreateObject("System.Collections.ArrayList")
    For i = 0 To .ListCount - 1
        dar1.Add .List(i)
    Next i
    dar1.Sort
    ListBox1.List = dar1.toarray()
    
    'get dar value back to selected item
    dar.Sort
    For i = 0 To dar.Count - 1
    .List(i) = dar.toarray()(i)
    .Selected(i) = True
    Next

End With

End Sub



Private Sub UserForm_Initialize()

Dim dar As Object, r As Range
ListBox1.MultiSelect = fmMultiSelectMulti
Set dar = CreateObject("System.Collections.ArrayList")
For Each r In Range("A2", Cells(Rows.Count, "A").End(xlUp))
dar.Add r.Value
Next
dar.Sort
ListBox1.List = dar.toarray()

Set dar = Nothing

Set dar = CreateObject("System.Collections.ArrayList")
For Each r In Range("B2", Cells(Rows.Count, "B").End(xlUp))
dar.Add r.Value
Next
dar.Sort
ComboBox1.List = dar.toarray()

End Sub

This the workbook:
https://www.dropbox.com/s/ttm0pqmtcd...list.xlsm?dl=0

Amazing show! You sure know how to code!
I'm speechless.
Thank you for your time on this and keep in mind that i appreciate your knowledge very much

Originally Posted by kosherboy

Amazing show! You sure know how to code!
I'm speechless.
Thank you for your time on this and keep in mind that i appreciate your knowledge very much

You're welcome & thanks for your kind word.