How to select an entire column after a certain row macro

[HushHoney]

Hey guys here is my code which works fine, however could anyone point me in the right direction of how I copy the entire column
but after for example row 3.

so for example if I wanted to copy column A but after row 3, I hope that makes sense.

code I have is below.

Sub HorizontalLoop()
    Dim lCol As Long
    
     
     Sheets("output").Select
    For lCol = 1 To 100
    
Dim inputrange As String



    If Not IsEmpty(Cells(lCol).Value) Then
    inputrange = Cells(1, lCol).Value
    
    
    Cells(1, lCol).EntireColumn.Select
    Selection.Copy
    Sheets("input").Select
    ActiveSheet.range(inputrange).Select
    ActiveSheet.Paste
    Sheets("output").Select
    
       End If
       
    Next lCol
End Sub

any help would be much appreciated

Thanks
H

[walruseggman]

if I wanted to copy column A but after row 3

Like so:

Range("A3:A" & Cells(Rows.Count, "A").End(xlup).Row).Copy

[AlphaFrog]

Try this...

Sub HorizontalLoop()
    
    Dim lCol       As Long
    Dim inputrange As String
    
    With Sheets("output")
        For lCol = 1 To 100
            inputrange = .Cells(1, lCol).Value
            If inputrange <> "" Then
                .Range(.Cells(3, lCol), .Cells(Rows.Count, lCol).End(xlUp)).Copy _
                    Destination:=Sheets("input").Range(inputrange)
            End If
        Next lCol
    End With
    
End Sub