VBA code to copy range of table from Excel 2010 to (existing) ppt (looping through a list)

Good day/evening,
I am searching for a simple VBA code which is doing the following (in the attached example):
1/ Looping through the cell A1 of the sheet "Outputtable" (so first for Electricity, then for Nitrogen, etc.) and
2/ Copying the corresponding data of the table range of A1:F3 to a powerpoint in separate slides (1 for Electricity, 1 for Nitrogen).
3/ With "good" positioning to put comments below the table range.
I am using Excel 2010, accordingly Power point.
Thanks a lot for any support.
Best regards
Heinz

Hello Heinz,

try this code:

Option Explicit

Sub testList()
Dim ws As Worksheet
Dim rg As Range, x&
Dim rList As Range, cell As Range

Dim ppApp As Object
Dim ppPres As Object
Dim sl As Object, sh As Object

Set ws = ThisWorkbook.Worksheets("Outputtable")
Set rg = ws.Range("A1")
Set rList = ThisWorkbook.Sheets("List").Range("A2:A" & Sheets("List").Range("A" & Rows.Count).End(xlUp).Row)

On Error Resume Next
    Set ppApp = GetObject(class:="PowerPoint.Application")
    Err.Clear
    If ppApp Is Nothing Then
        Set ppApp = CreateObject(class:="PowerPoint.Application")
    End If
    
    If Err.Number = 429 Then
        MsgBox "PowerPoint Apps not found - terminating..."
        Exit Sub
    End If
On Error GoTo 0

On Error GoTo ErrHandler
Application.ScreenUpdating = False

Set ppPres = ppApp.Presentations.Add

x = 0
For Each cell In rList
    rg.Value = cell.Value
    ws.Range("A1").CurrentRegion.Copy
    Set sl = ppPres.Slides.Add(1 + x, 12)
    sl.Shapes.PasteSpecial DataType:=2
    Set sh = sl.Shapes(sl.Shapes.Count)
    sh.Left = 200
    sh.Top = 80
    x = x + 1
Next cell

ppApp.Visible = True
ppApp.Activate
Application.ScreenUpdating = True
Application.CutCopyMode = False
Exit Sub

ErrHandler:
Application.ScreenUpdating = True
MsgBox ("An error has occured:" & vbLf & Err.Number & " : " & Err.Description), vbOKOnly + vbInformation

End Sub

Make sure you have set reference to Microsoft PowerPoint Object Library. I'm sorry I could not find out how to upload the file.
Will do later when I get how to..

Regards,
sysss

Hi again,

now with the file.

s.

Dear sysss,
Perfect, many thanks, works very well. Great.
Best regards
Heinz

Hello Heinz,

I'm really glad to help you.
Please, If you're satisfied with the solution mark this thread as solved (tools in the top).
And you can help me too .. so if you happy and your issue solved there is a little star on left...

Thanks
Have a nice day
sysss