Generate output form from spreadsheet data

Attach that as a sample workbook - it's hard to work from an image...

I apologize.. I wasn't thinking that one through haha
http://www.filedropper.com/shippedinventorybuilder

Try:

Option Explicit

Const lFormColumn As Long = 10

Sub GenerateForm()
    Dim c As Range
    Dim cA As Range
    Dim cB As Range
    Dim i As Integer
    
    Set c = Columns(1).Find("Shipped to")
    WriteToForm String(18, "-")
    WriteToForm "::Shipped To::"
    WriteToForm String(18, "-")
    If Not c Is Nothing Then
        For Each cB In Intersect(c.CurrentRegion, Columns(2)).Cells
            If Not cB.Row = 1 And Not cB.Value = "" Then WriteToForm cB.Value
        Next cB
    End If
    
    Set c = Columns(1).Find("Contents Shipped")
    WriteToForm Chr(1)
    WriteToForm String(18, "-")
    WriteToForm "::Contents Shipped::"
    WriteToForm String(18, "-")
    If Not c Is Nothing Then
        For Each cB In Intersect(c.CurrentRegion, Columns(2)).Cells
            WriteToForm cB.Value
            For i = 1 To 4
                WriteToForm "- " & Cells(1, i + 2).Value & ": " & NullNA(cB.Offset(0, i).Value)
            Next i
        Next cB
    End If
End Sub

Function WriteToForm(ByVal s As String)
    Dim i As Integer
    i = Abs(Application.CountA(Columns(lFormColumn)) > 0)
    If s = "" Then s = "N/A"
    Cells(Rows.Count, lFormColumn).End(xlUp).Offset(i, 0).Value = s
End Function

Function NullNA(ByVal s As String)
    If s = "" Then
        NullNA = "N/A"
    Else
        NullNA = s
    End If
End Function

How to install your new code

1. Copy the Excel VBA code
2. Select the workbook in which you want to store the Excel VBA code
3. Press Alt+F11 to open the Visual Basic Editor
4. Choose Insert > Module
5. Edit > Paste the macro into the module that appeared
6. Close the VBEditor
7. Save your workbook (Excel 2007+ select a macro-enabled file format, like *.xlsm)

To run the Excel VBA code:

1. Press Alt-F8 to open the macro list
2. Select a macro in the list
3. Click the Run button