Codepended Check Boxes

[igormigor]

Hi all,

I have 2 check boxes in sheet. Each of them controls separate cell. If I check Box1, cell B12 will show "True". If I check Box2, cell B14 will show "True".
I need when I check one of the boxes, the other one automatically to be unchecked. In same time only one box can be checked.

Below is my code. There is conflict in it and does not work properly.

Private Sub CheckBox1_Click()
If CheckBox1.Value = True Then
        Range("B12").Value = True
        CheckBox2.Value = False
        End If
If CheckBox1.Value = False Then
        Range("B12").Value = False
        CheckBox2.Value = True
        End If
End Sub

Private Sub CheckBox2_Click()
If CheckBox2.Value = True Then
        Range("B14").Value = True
        CheckBox1.Value = False
        End If
If CheckBox1.Value = False Then
        Range("B14").Value = False
        CheckBox1.Value = True
        End If
End Sub

Any ideas how to fix this?

Thank you

Igor

[Kaper]

Hi Igor,

If I understood you well, you are using ActiveX Cheeckboxes, and want to have always one checked and the other not (may be not in initial state, but once one is checked first time).
In this case you probably do not really need two checkboxes, one would be enough. but:

Private Sub CheckBox1_Click()
If CheckBox1.Value = True Then
        Range("B12").Value = True
        CheckBox2.Value = False
        Range("B14").Value = False
        End If
If CheckBox1.Value = False Then
        Range("B12").Value = False
        CheckBox2.Value = True
        Range("B14").Value = True
        End If
End Sub

and similar code, but with opposite references for the second one

[Kaper]

But if you allow 3 options any time:
- both false
- 1st true 2nd false
- 1st false 2nd true
try:

Private Sub CheckBox1_Click()
If CheckBox1.Value = True Then
        Range("B12").Value = True
        CheckBox2.Value = False
        Range("B14").Value = False
        End If
If CheckBox1.Value = False Then
        Range("B12").Value = False
        End If
End Sub

Private Sub CheckBox2_Click()
If CheckBox2.Value = True Then
        Range("B14").Value = True
        CheckBox1.Value = False
        Range("B12").Value = False
        End If
If CheckBox2.Value = False Then
        Range("B14").Value = False
        End If
End Sub

or shorter:

Private Sub CheckBox1_Click()
Range("B12").Value = CheckBox1.Value
If CheckBox1.Value Then
   CheckBox2.Value = False
   Range("B14").Value = False
End If
End Sub

(and similar but opposite for second one)

[igormigor]

Hi Kaper,

THATS PERFECT!!!!!
for me works the second option.

Thank you a lot!!!.
Igor