Populate count & sum based on equal to & not equal to factors

Looks more like something that would be better handled with formulas.

Try this for the count...
=SUM(COUNTIFS(Register!D:D,[@Date],Register!E:E,6,Register!H:H,{"REFER","CLOSE","STOP","NSF"},Register!A:A,"<>Z99999"))

Hi jscalem

If the Formula approach works for you, fine.

If not, try this...

Sub Populate_Chargebacks()
   Dim ws           As Worksheet
   Dim ws1          As Worksheet
   Dim LR           As Long
   Dim Rng          As Range
   Dim Rng1         As Range
   Dim cel          As Range
   Dim c            As Range

   Set ws = Sheets("Register")
   Set ws1 = Sheets("Chargebacks")

   Application.ScreenUpdating = False
   With ws
      LR = .Cells.Find("*", .Cells(.Rows.Count, .Columns.Count), SearchOrder:=xlByRows, _
                       SearchDirection:=xlPrevious).Row
      If Not .AutoFilterMode Then
         .Rows("1:1").AutoFilter
      End If

      .Range("A1:T" & LR).AutoFilter Field:=8, Criteria1:=Array( _
                                                          "NSF", "REFER", "CLOSE", "STOP"), Operator:=xlFilterValues
      .Range("A1:T" & LR).AutoFilter Field:=5, Criteria1:="6"
      .Range("A1:T" & LR).AutoFilter Field:=1, Criteria1:= _
                                     "<>Z99999", Operator:=xlAnd
      Set Rng = .Range(.Cells(2, "D"), .Cells(LR, "D")).SpecialCells(xlCellTypeVisible)
      Set Rng1 = ws1.Columns(1)
      For Each cel In Rng
         Set c = Rng1.Find(Format(cel.Value, "d-mmm-yy"), , xlValues, xlWhole, xlByRows, xlNext, False)
         If Not c Is Nothing Then
            ws1.Cells(c.Row, "F").Value = ws1.Cells(c.Row, "F").Value + 1
            ws1.Cells(c.Row, "G").Value = ws1.Cells(c.Row, "G").Value + cel.Offset(0, 2).Value
         End If
      Next cel
      .AutoFilterMode = False
   End With
   Application.ScreenUpdating = True
End Sub

You're welcome...glad I could help. Thanks for the Rep.

If this resolves your issue please mark the Thread as Solved.

Select Thread Tools-> Mark thread as Solved. To undo, select Thread Tools-> Mark thread as Unsolved.

Hi jscalem

Try this...

Option Explicit

Sub Populate_Chargebacks()
   Dim ws           As Worksheet
   Dim ws1          As Worksheet
   Dim LR           As Long
   Dim Rng          As Range
   Dim Rng1         As Range
   Dim cel          As Range
   Dim c            As Range

   Set ws = Sheets("Register")
   Set ws1 = Sheets("Chargebacks")

   Application.ScreenUpdating = False
   With ws
      LR = .Cells.Find("*", .Cells(.Rows.Count, .Columns.Count), SearchOrder:=xlByRows, _
                       SearchDirection:=xlPrevious).Row
      If Not .AutoFilterMode Then
         .Rows("1:1").AutoFilter
      End If

      .Range("A1:T" & LR).AutoFilter Field:=8, Criteria1:=Array( _
                                                          "NSF", "REFER", "CLOSE", "STOP"), Operator:=xlFilterValues
      .Range("A1:T" & LR).AutoFilter Field:=5, Criteria1:="6"
      .Range("A1:T" & LR).AutoFilter Field:=1, Criteria1:= _
                                     "<>Z99999", Operator:=xlAnd

      If Not .AutoFilter.Range.Columns(1).SpecialCells(xlCellTypeVisible).Count - 1 = 0 Then
         Set Rng = .Range(.Cells(2, "D"), .Cells(LR, "D")).SpecialCells(xlCellTypeVisible)
         Set Rng1 = ws1.Columns(1)
         For Each cel In Rng
            Set c = Rng1.Find(Format(cel.Value, "d-mmm-yy"), , xlValues, xlWhole, xlByRows, xlNext, False)
            If Not c Is Nothing Then
               ws1.Cells(c.Row, "F").Value = ws1.Cells(c.Row, "F").Value + 1
               ws1.Cells(c.Row, "G").Value = ws1.Cells(c.Row, "G").Value + cel.Offset(0, 2).Value
            End If
         Next cel
      Else: MsgBox "No records found"
      End If
      .AutoFilterMode = False
   End With
   Application.ScreenUpdating = True
End Sub

If you want a count

Formula:

=SUM(COUNTIFS(Register!A2:A10345,"<>Z99999",Register!E2:E10345,6,Register!H2:H10345,{"REFER","CLOSE","STOP","NSF"}))

Enter with Ctrl + Shift + Enter

If you want the total from column E make a helper column U on the Register and enter this formula and fill down.

Formula:

=IF(AND(A2<>"Z99999",E2=6,OR(H2="REFER",H2="CLOSE",H2="STOP",H2="NSF")),1,"")

Enter this formula for the sum

Formula:

=SUMIF(Register!U2:U10345,1,Register!F2:F10345)