how do I Use Greater than ("Cell") to bring up a msgbox

[Wouldsman]

I am trying to bring up a msgbox if the number they enter into cell ("F3") is greater than 99999.
also if this is true I want it to select ("F3") again so they can try again.

I have the following code and I thought it should work but it doesn't.
Any thoughts?

Private Sub Worksheet_Change2()
Dim JobNo As Integer, result As String
 JobNo = Range("F3").Value

If JobNo > 99999 Then MsgBox "Numbers may not exceed 99999"

 Range("F3").Select
End If
    End Sub

[TMS]

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)

Const ciMax As Long = 99999

Dim rInterest As Range
Set rInterest = Range("F3")

If Target.Cells.Count > 1 Then Exit Sub
If Intersect(Target, rInterest) Is Nothing Then Exit Sub

With Target
    If .Value > ciMax Then
        MsgBox "Numbers may not exceed 99999"
        .Select
    End If
End With

End Sub

Regards, TMS

[LeoTaxi]

or

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$F$3" And Target.Value > 99999 Then
    MsgBox "Numbers may not exceed 99999"
    Application.Goto Reference:=Range("F3"), scroll:=False
End If
End Sub

Kind regards
Leo