How to transpose rows for 3 different columns?

Hey Ali,
Here's the link to the workbook as you requested.
https://www.dropbox.com/s/fmhie2u1zd...jor8.xlsx?dl=0
The main file is very huge with over 170,000 rows.

To answer your question:
There is 17 degree types. Not all schools have all 17 degree types. Some have 12. Some have 2. Some have 10, etc.

What should be the main title for this Excel request?

This will take time for about 5 min to finish.

Run it at your own risk.

Sub test()
    Dim a, i As Long, txt As String, dic As Object, e, v, n As Long, x
    [g1].CurrentRegion.ClearContents
    Set dic = CreateObject("Scripting.Dictionary")
    dic.CompareMode = 1
    a = Cells(1).CurrentRegion.Value
    With CreateObject("Scripting.Dictionary")
        For i = 2 To UBound(a, 1)
            If Not .exists(a(i, 1)) Then
                Set .Item(a(i, 1)) = CreateObject("Scripting.Dictionary")
            End If
            If Not .Item(a(i, 1)).exists(a(i, 2)) Then
                Set .Item(a(i, 1))(a(i, 2)) = CreateObject("Scripting.Dictionary")
            End If
            x = Split(a(i, 3), "'")(0)
            If Not dic.exists(x) Then dic(x) = dic.Count
            .Item(a(i, 1))(a(i, 2))(x) = .Item(a(i, 1))(a(i, 2))(x) + a(i, 4)
            DoEvents
        Next
        [g1].Resize(, 2).Value = a
        [i1].Resize(, dic.Count).Value = dic.keys
        For Each e In .keys
            For Each v In .Item(e).keys
                n = n + 1
                [g1].Offset(n).Resize(, 2).Value = Array(e, v)
                For Each x In .Item(e)(v).keys
                    [i1].Offset(n, dic(x)).Value = .Item(e)(v)(x)
                Next
            Next
            DoEvents
        Next
    End With
End Sub

As an alternative :

Sub MyTest()
  Dim collSchollDegree As New Collection, collLevel As New Collection
  Dim arrIn, arrOut(), i As Long, p1 As Long, p2 As Long, str1 As String

  arrIn = Range("A1").CurrentRegion.Resize(, 5).Value
  On Error Resume Next
     For i = 2 To UBound(arrIn, 1)
         str1 = Split(arrIn(i, 3), "'")(0): arrIn(i, 5) = str1
         collLevel.Add Key:=str1, Item:=Array(str1, collLevel.Count + 1)
         collSchollDegree.Add Key:=arrIn(i, 1) & Chr(2) & arrIn(i, 2), Item:=collSchollDegree.Count + 1
     Next i
  On Error GoTo 0

  ReDim arrOut(1 To (collSchollDegree.Count + 1), 1 To (collLevel.Count + 2))
  arrOut(1, 1) = "school": arrOut(1, 2) = "degree": For i = 1 To collLevel.Count: arrOut(1, i + 2) = collLevel(i)(0): Next i
  For i = 2 To UBound(arrIn, 1)
      p1 = collSchollDegree(arrIn(i, 1) & Chr(2) & arrIn(i, 2)) + 1
      p2 = collLevel(arrIn(i, 5))(1) + 2
      arrOut(p1, 1) = arrIn(i, 1)
      arrOut(p1, 2) = arrIn(i, 2)
      arrOut(p1, p2) = arrOut(p1, p2) + arrIn(i, 4)
  Next i
  Range("G1").Resize(UBound(arrOut, 1), UBound(arrOut, 2)).Value = arrOut
  MsgBox "Done"
End Sub

Hey jindon and karedog,
Both your VBAs work! Thank you so much!
I love you guys!
+ rep for both of you