Check domain availability

[YasserKhalil]

Hello everyone
I have this URL that checks the avaiability of any domain

http://www.p5s.net/whois/mwhois.php

For example : typing "google" and pressing "بدء البحث" button >> will result in "محجوز" which means "Reserved"
Another example: typing "halloexcel" >> will result in "متوفر" which means "Available"

I need to create UDF function or vba code that checks the domain and returns either "Reserved" or "Available"
Hope it is clear

Thanks advanced for help

[YasserKhalil]

Any help with this topic please?

[karedog]

Maybe :

Sub Test()
  Dim arrIn, arrOut(), i As Long, strURL As String, strPostData As String, str1 As String

  arrIn = Range("A2:B" & Cells(Rows.Count, "A").End(xlUp).Row)
  ReDim arrOut(1 To UBound(arrIn, 1), 1 To 1)
  strURL = "http://www.p5s.net/whois/mwhois.php"

  With CreateObject("WinHttp.WinHttpRequest.5.1")
    For i = 1 To UBound(arrIn, 1)
        If Len(arrIn(i, 1)) Then
           strPostData = "domain=" & arrIn(i, 1) & "&ext=" & arrIn(i, 2)
           .Open "POST", strURL, False
           .setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
           .Send (strPostData)
           str1 = .ResponseText
           If InStr(1, str1, "<FORM action=""order.html"">") Then arrOut(i, 1) = "Available"
           If InStr(1, str1, "<FORM action=""mwhois.php""") Then arrOut(i, 1) = "Reserved"
        End If
    Next i
  End With

  Range("C2").Resize(UBound(arrOut, 1), UBound(arrOut, 2)).Value = arrOut
End Sub

[YasserKhalil]

Really amazing .. Really wonderful
With your perfect solutions I feel that I'm in a dream (of course happy dream)
Thank you very very much for all this perfect and great help

[karedog]

You are welcome.
It seemed that my posts have a "psychotropic dream effect"
Maybe I should stop coding, and start to selling some drugs


Regards