How to AutoFill from Last Column down to Last Row

[tuongtu3]

Hello All,
I need help to autofill the formula from last column down to the last row. Please help me to fix the below:

Dim LCc As Long, LRr As Long
Set LCc = Sheets("GEN2_CSP").Range("A1").End(xlToRight).Offset(0, 1)
LCc.Formula = "=IFERROR(1/(1/SUMIF(BA:BA,B1,BD:BD)),"""")"
Dim LRr As Long
LRr = Range("A" & Rows.Count).End(xlUp).Row
    With LCc
        .AutoFill Destination:=Range("LCc" & LRr).Resize(, 1), Type:=xlFillSeries  <=== got error here
    End With

Regards,
tt3

[TMS]

Maybe:

Dim LCc As Long, LRr As Long
With Sheets("GEN2_CSP")
    LCc = .Range("A1").End(xlToRight).Offset(0, 1).Column
    LRr = .Range("A" & .Rows.Count).End(xlUp).Row
    .Cells(1, LCc).Resize(LRr).Formula = "=IFERROR(1/(1/SUMIF(BA:BA,B1,BD:BD)),"""")"
End With

Regards, TMS

[tuongtu3]

Hi TMS,
The code works and after done: how to enter the Formula at the last column= "=SUM(F2:" & Last Column)"
(let say last column is AA then Formula at AB2 .Formula = "=SUM("F2:AA2")"

Regards,
tt3

[TMS]

Sub Test2()
Dim LCc As Long, LRr As Long
With Sheets("GEN2_CSP")
    LCc = .Cells(1, .Columns.Count).End(xlToLeft).Column
    LRr = .Range("A" & .Rows.Count).End(xlUp).Row
    .Cells(2, LCc + 1).Resize(LRr - 1).Formula = "=SUM(F2:" & Split(Cells(2, LCc).Address, "$")(1) & "2)"
End With
End Sub

Regards, TMS