VBA: Getting signature data from signed and unsigned signature blocks

I am using Microsoft Office 2013.

I have a number of Excel and Word documents all of which contain a number of signature blocks.
I want to be see which signature blocks have been signed and which ones have not been signed.
My problem is that in the simplified VBA code below Signatures.Count only returns the number of SIGNED blocks.
How do I get data from both signed and unsigned signature blocks.

Sub getsigdata()

Dim signer As String

countsigs = ActiveDocument.Signatures.Count

If countsigs > 0 Then
For i = 1 To countsigs

signer = ActiveDocument.Signatures.Item(i).Setup.SuggestedSigner
MsgBox (signer)
Next i

End If

End Sub

You've probably found the answer by now but this is for people like me

…

    Dim wb As Workbook
    
    Dim sig_nb As Long ' number of signature in document
    Dim sig_signed As Long ' number of signed signature in document
    Dim sig_unsigned As Long ' number of unsigned signature in document
    
    Set wb = ThisWorkbook
    
    wb.Signatures.Subset = msoSignatureSubsetSignatureLines
    
    sig_nb = wb.Signatures.Count
    
    wb.Signatures.Subset = msoSignatureSubsetSignatureLinesSigned
    
    sig_signed = wb.Signatures.Count
    
    wb.Signatures.Subset = msoSignatureSubsetSignatureLinesUnsigned
    sig_unsigned = wb.Signatures.Count
    
    If sig_nb = 0 Then
        MsgBox "Workbook has no signature", vbOKOnly
    Else
        MsgBox "Workbook has " & sig_nb & "signature", vbOKOnly
    End If

    If sig_signed = 0 Then
        MsgBox "Workbook has no signed signature", vbOKOnly
    Else
        MsgBox "Workbook has " & sig_signed & " signed signature", vbOKOnly
    End If

    If sig_unsigned = 0 Then
        MsgBox "Workbook has no unsigned signature", vbOKOnly
    Else
        MsgBox "Workbook has " & sig_unsigned & " unsigned signature", vbOKOnly
    End If