Remove blank lines of code

Hello everybody
I need a macro that enables me to clear the lines of code (blank of course)
I have very long code which has blank lines in between ..
I need a quick way to clear these blank lines so as to be easy to read and I can check it carefully
Doing that task manually is very boring process specially with long macros

For example:

Sub Example()


MsgBox "Hello"



Range("A1").Value = "ExcelForum"



Debug.Print "Thank you"



End Sub

would be

Sub Example()
MsgBox "Hello"
Range("A1").Value = "ExcelForum"
Debug.Print "Thank you"
End Sub

use with caution as it will delete original contents of module

Sub StripBlankLines()

    Dim Code As Object  'CodeModule
    Dim Text As String
    Dim Index As Long
    Dim NewText As String
    
    Set Code = ThisWorkbook.VBProject.VBComponents("Module1").CodeModule
    For Index = 1 To Code.CountOfLines
        If Len(Trim(Code.Lines(Index, 1))) > 0 Then
            NewText = NewText & Code.Lines(Index, 1) & vbLf
        End If
    Next
    Debug.Print NewText
    Code.DeleteLines 1, Code.CountOfLines
    Code.AddFromString NewText
    
End Sub

put code in a new module within vbproject. change module name to suit

Mr. Andy Pope The Genius
Thanks a lot for this perfect solution.
Best Regards