Look for specific text string, insert row below, insert text to that row

Hello everyone,

I need to modify some very large router configurations for 20+ routers and need to look for a string, for examples sake: String: primary "igp", does the next row contain the text adaptive? no, insert a row below it, and add the word, adaptive, if it does contain adaptive, move on. The reason for needing to search for the text strings is that some of the data will already contain the word adaptive and doesn't need to change, and the row count between the text may change if additional commands are on that configuration. Meaning I can't do a "count 10 rows, insert row, insert text" type macro, it has to look for the text strings.

Book2.xlsm

Originally Posted by AlphaFrog

This uses the .Find method

Sub Routers()
    
    Dim Found As Range, FirstFound As String, counter As Long
        
    Application.ScreenUpdating = False
        
    Set Found = Range("A:A").Find(What:="primary ""igp""", _
                                  LookIn:=xlValues, _
                                  LookAt:=xlPart, _
                                  SearchOrder:=xlByRows, _
                                  SearchDirection:=xlNext, _
                                  MatchCase:=False)
                
    If Not Found Is Nothing Then
        
        FirstFound = Found.Address
        
        Do
            If InStr(1, Found.Offset(1), "Adaptive", 1) = 0 Then
                Found.Offset(1).Insert Shift:=xlShiftDown
                counter = counter + 1
            End If
            
            Set Found = Range("A:A").FindNext(After:=Found)
            
        Loop Until Found.Address = FirstFound
        
    End If
    
    Application.ScreenUpdating = True
    
    MsgBox counter & " rows inserted. ", vbInformation, "Adaptive Inserts Complete"
    
End Sub

AlphaFrog,

This is very close, but when I run the code it finds primary "igp" and inserts blank row, but doesn't put the word adaptive, it does however leave the rows alone that already have adaptive. Can you have a second look?

Maybe:

Sub jwats()
Dim i As Long
With Application
    .ScreenUpdating = False
    .Calculation = xlManual
    .EnableEvents = False
End With
For i = Range("A" & Rows.Count).End(3).row To 2 Step -1
    If Cells(i, "A") Like "*igp*" And Cells(i + 1, "A") <> "adaptive" Then
        Rows(i + 1).Insert
        Cells(i + 1, "A") = "adaptive"
    End If
Next i
With Application
    .EnableEvents = True
    .Calculation = xlAutomatic
    .ScreenUpdating = True
End With
End Sub

Perfect my friend! Worked just as intended on my test data. I will do some testing with it to make sure I can't break it, lol one must be very careful running a production routers config through Excel