Can't delete hidden rows in bulk

A potential problem with the solution by 'bmouse' is that the rows are renumbered whenever one of them is deleted.
If row 9 is hidden, it gets deleted and then row 10 becomes row 9 but the loop will move on to the new row 10, skipping the previous row 10 which is now row 9. Does that make sense?

The cure for this is to work backwards or from the bottom up.

It will be speedier too when screen updating is turned off

Sub Delete_Hidden_Rows()
  Application.ScreenUpdating = False
  Dim rowNum as Long

  For rowNum = 25000 to 1 step -1
    If Rows(rowNum).Hidden = True Then 
      Rows(rowNum).Delete
    End If
  Next rowNum

  Application.ScreenUpdating = True
End Sub

Maybe this:

Option Explicit

Sub sDeleteHiddenRows()

Dim rAll As Range, rVisible As Range, rDelete As Range, cell As Range
Set rAll = Range("A1:A100")
Set rVisible = Range("A1:A100").SpecialCells(xlCellTypeVisible)

Application.ScreenUpdating = False
For Each cell In rAll
    If Intersect(cell, rVisible) Is Nothing Then
        If rDelete Is Nothing Then
            Set rDelete = cell
        Else
            Set rDelete = Union(rDelete, cell)
        End If
    End If
Next cell

If Not rDelete Is Nothing Then rDelete.EntireRow.Delete
Application.ScreenUpdating = True

End Sub

Regards, TMS

Maybe:

Sub forrestgump1980()
Dim x As Long, y As Long
With Application
    .ScreenUpdating = False
    .Calculation = xlCalculationManual
End With
y = ActiveSheet.UsedRange.Columns.Count
x = Range("A" & Rows.Count).End(3).row
With Range(Cells(1, y + 1), Cells(x, y + 1))
    .SpecialCells(12).Value = "Keep"
    .EntireRow.Hidden = False
    .AutoFilter 1, "<>Keep", xlWhole
    .SpecialCells(12).EntireRow.Delete
    .Delete
End With
ActiveSheet.AutoFilterMode = False
With Application
    .ScreenUpdating = True
    .Calculation = xlCalculationAutomatic
End With
End Sub

I think John's solution would work well for removing the rows in place, and Crispy85's suggestion would be good if you want to move the data to another sheet.

Be interesting to time the different approaches.

Regards, TMS