I need to hide column f or column g based on text in cell b2

[A440]

Hi,
I need to hide column f or column g based on text in cell b2, I would like the 2 column to auto switch if possible please.

If "B2" contains "Darrell" so hide column "G" and un hide column "F".
If "B2" contains "Brendon" hide column "F" and un hide column "G".
If "B2" is empty un hide "F" & "G"

Any help is always much appreciated.

[BellyGas]

This is so easy I'm wondering why you're asking. You can turn on the macro recorder and hide / unhide columns F & G.,...and then put an If range("B2").value =......statement to do the rest.

If you're not sure about how to use the macro recorder or what an If statement is then I suggest starting here: http://www.excelforum.com/excel-prog...materials.html

[A440]

It's only that easy when you know how! Thanks for the link.

[bmouse]

I think this should do it.

Here is the code itself:

Sub Hide_Unhide()
    
If Cells(2, "B").Value = "Darrel" Then

    Columns("G").Hidden = True
    Columns("F").Hidden = False
    
Else
    
    If Cells(2, "B").Value = "Brendon" Then
    
        Columns("G").Hidden = False
        Columns("F").Hidden = True
        
    Else
    
        If Cells(2, "B").Value = nul Then
        
            Columns("G").Hidden = False
            Columns("F").Hidden = False
            
        Else
        End If
    End If
End If
        
     
End Sub

[A440]

Many thanks bmouse, brilliant!

[StuCram]

Here's a similar version that will do the task automatically when cell B2 is changed.
By using SELECT / CASE structure instead of IF / ELSEIF, you can easily add more values if needed.
Place this in the code section for the sheet you are working with.

Private Sub Worksheet_Change(ByVal Target As Range)
  ' For Excel Forum, Aug 3, 2015; user A440. 
  '   I need to hide column f or column g based on text in cell b2, I would like the 2 column to auto switch if possible please.
  '   If "B2" contains "Darrell" so hide column "G" and un hide column "F".
  '   If "B2" contains "Brendon" hide column "F" and un hide column "G".
  '   If "B2" is empty un hide "F" & "G"
  
  If Intersect(Target, Range("B2")) Is Nothing Then Exit Sub
  Application.EnableEvents = False
  
  Select Case Target
  
    Case Is = "Darrell"
      Columns("G").Hidden = True
      Columns("F").Hidden = False
      
    Case Is = "Brendon"
      Columns("G").Hidden = False
      Columns("F").Hidden = True
      
    Case Else
      Columns("G").Hidden = False
      Columns("F").Hidden = False
      
  End Select
  
  Application.EnableEvents = True
End Sub

[A440]

Thank you very much StuCram this is exactly what I wonted.