Double Listbox movement - Maintain Order

Hi and welcome to the forum.

Try this...

Private Sub UserForm_Initialize()
    
'Adds values to Listbox based on selected ranges.
    
    ListBox1.List = Worksheets("Sheet1").Range("B12:B26").Value
    
    ListBox1.MultiSelect = fmMultiSelectMulti
    ListBox2.MultiSelect = fmMultiSelectMulti
 
End Sub


Private Sub CommandButton8_Click()
    
    'This code is used to add the selected item from the LEFT listbox to the one on the RIGHT
    
    Dim i As Long
    
    'Remove selected items from ListBox1
    If ListBox1.ListCount > 0 Then
        For i = ListBox1.ListCount - 1 To 0 Step -1
            If ListBox1.Selected(i) Then ListBox1.RemoveItem i
        Next i
    End If
    
    'Populate Listbox2 with all items.
    ListBox2.List = Worksheets("Sheet1").Range("B12:B26").Value
    'Remove remianing items in Listbox1 from Listbox2
    For i = ListBox2.ListCount - 1 To 0 Step -1
        If ListBox1.ListCount = 0 Then Exit For
        If IsNumeric(Application.Match(ListBox2.List(i), ListBox1.List, 0)) Then ListBox2.RemoveItem i
    Next i
    
End Sub


Private Sub CommandButton9_Click()
    
    'This code is used to add the selected item from the RIGHT listbox to the one on the LEFT
    
    Dim i As Long
    
    'Remove selected items from ListBox2
    If ListBox2.ListCount > 0 Then
        For i = ListBox2.ListCount - 1 To 0 Step -1
            If ListBox2.Selected(i) Then ListBox2.RemoveItem i
        Next i
    End If
    
    'Populate Listbox1 with all items.
    ListBox1.List = Worksheets("Sheet1").Range("B12:B26").Value
    'Remove remianing items in Listbox2 from Listbox1
    For i = ListBox1.ListCount - 1 To 0 Step -1
        If ListBox2.ListCount = 0 Then Exit For
        If IsNumeric(Application.Match(ListBox1.List(i), ListBox2.List, 0)) Then ListBox1.RemoveItem i
    Next i
    
End Sub

You are amazing . I had actually done a much more complicated thing haha. I got mine to work too, but yours makes much more sense. I basically did it step by step for what I wanted to happen.

i.e.
1. Select - Move selected
2. Clear list 1
3. Put all in List 1
4. Select what's in List 2 in List 1
5. Clear List 2
6. Move stuff from list 1 to List 2
7. Delete these "stuff" from list 1

Haha. Well it works, thanks so much buddy . Just for your information, and not to lose information; my code:

Private Sub CommandButton8_Click()
Dim counter As Integer
counter = 0

'This code is used to add the selected item from the LEFT listbox to the one on the RIGHT

For i = 0 To ListBox1.ListCount - 1
    If ListBox1.Selected(i) = True Then
    ListBox2.AddItem ListBox1.List(i)
    End If
Next i

ListBox1.Clear

ListBox1.List = Worksheets("Sheet1").Range("B12:B26").Value

For t = 0 To ListBox2.ListCount - 1
    For r = 0 To ListBox1.ListCount - 1
        If ListBox1.List(r) = ListBox2.List(t) Then
            ListBox1.Selected(r) = True
        End If
    Next r
Next t

ListBox2.Clear

For o = 0 To ListBox1.ListCount - 1
    If ListBox1.Selected(o) = True Then
    ListBox2.AddItem ListBox1.List(o)
    End If
Next o

'This code below is used to remove the same selected item from the LEFT listbox, so there aren't 2 values of the same thing. And when
'transfering back, doesn't cause repeats.
'Counter is used to keep track of items that have been removed

For q = 0 To ListBox1.ListCount - 1
    If ListBox1.Selected(q - counter) = True Then
        ListBox1.RemoveItem (q - counter)
        counter = counter + 1
    End If
Next q


End Sub

You're welcome. Thanks for the feedback.

Hey AlphaFrog, I have one more question. Since you showed me how to add to list the range...

ListBox1.List = Worksheets("Sheet1").Range("B12:B26").Value

How would I do it if it my range was C2, D2, E2, ... , O2 and then Q2 - T2, V2, W2, Y2 - AA2 ?

As in.. I have columns seperated in the middle. So I cant add the full range.

Listbox1.List = Worksheets("Sheet1").Range("C2:O2").Value
Listbox1.List = Worksheets("Sheet1").Range("Q2:T2").Value
Listbox1.List = Worksheets("Sheet1").Range("V2:W2").Value
Listbox1.List = Worksheets("Sheet1").Range("Y2:AA2").Value

PS: I know this doesn't work as this just changes the list to what the new range values are... but I'm wondering how to add them all.

This is what I currently have:

With Listbox1

    .AddItem Worksheets("Sheet1").Range("C2").Value
    .AddItem Worksheets("Sheet1").Range("D2").Value
    .AddItem Worksheets("Sheet1").Range("E2").Value
    .AddItem Worksheets("Sheet1").Range("F2").Value
    .AddItem Worksheets("Sheet1").Range("G2").Value
    .AddItem Worksheets("Sheet1").Range("H2").Value
    .AddItem Worksheets("Sheet1").Range("I2").Value
    .AddItem Worksheets("Sheet1").Range("J2").Value
    .AddItem Worksheets("Sheet1").Range("K2").Value
    .AddItem Worksheets("Sheet1").Range("L2").Value
    .AddItem Worksheets("Sheet1").Range("M2").Value
    .AddItem Worksheets("Sheet1").Range("N2").Value
    .AddItem Worksheets("Sheet1").Range("O2").Value
    .AddItem Worksheets("Sheet1").Range("Q2").Value
    .AddItem Worksheets("Sheet1").Range("R2").Value
    .AddItem Worksheets("Sheet1").Range("S2").Value
    .AddItem Worksheets("Sheet1").Range("T2").Value
    .AddItem Worksheets("Sheet1").Range("V2").Value
    .AddItem Worksheets("Sheet1").Range("W2").Value
    .AddItem Worksheets("Sheet1").Range("Y2").Value
    .AddItem Worksheets("Sheet1").Range("Z2").Value
    .AddItem Worksheets("Sheet1").Range("AA2").Value

End With

Or is there a simpler way, Could I seperate the ranges via comma?

    Dim cell As Range
    For Each cell In Worksheets("Sheet1").Range("C2:O2,Q2:T2,V2:W2,Y2:AA2")
        ListBox1.AddItem cell.Value
    Next cell