Restrict Userform Textbox to Numbers Only

As the title says I've been trying to make it so that a textbox on a userform can only have numbers entered into it with an error message popping up if letters are added.

The code I've used before doesn't seem to be working and I can't figure out why:

Private Sub txtAccount_Change()
    OnlyNumbers
End Sub

Private Sub txtAcres_Change()
    OnlyNumbers
End Sub

Private Sub txtLivestock_Change()
    OnlyNumbers
End Sub

Private Sub txtDirectors_Change()
    OnlyNumbers
End Sub

Private Sub txtShareholders_Change()
    OnlyNumbers
End Sub

Private Sub txtPartners_Change()
    OnlyNumbers
End Sub

Private Sub OnlyNumbers()
    If TypeName(Me.ActiveControl) = "TextBox" Then
        With Me.ActiveControl
            If Not IsNumeric(.Value) And .Value <> vbNullString Then
                MsgBox "Sorry, Only numbers allowed"
                .Value = vbNullString
            End If
        End With
    End If
End Sub

Any ideas on a fix or what is going wrong?

Hi Mousiefuzz,

My speculation is that you added a frame around the TextBox, and now the Frame is the Active Control.

The following code seemed to work for me with your file:

Private Sub OnlyNumbers()

    Dim sTypeName As String
    Dim sControlName As String
    Dim sValue As String
    
    'Get the TypeName of the Active Control and the Control Name
    sTypeName = TypeName(Me.ActiveControl)
    sControlName = Me.ActiveControl.Name
    
    'If the TypeName is 'Frame', get the TypeName of the Active Control
    'and the Control Name within the Frame
    If sTypeName = "Frame" Then
      sTypeName = TypeName(ActiveControl.ActiveControl)
      sControlName = ActiveControl.ActiveControl.Name
    End If

    'Test the Control for valid input
    If sTypeName = "TextBox" Then
        sValue = Me.Controls(sControlName).Value
        With Me.ActiveControl
            If Not IsNumeric(sValue) And sValue <> vbNullString Then
                MsgBox "Sorry, Only numbers allowed"
                Me.Controls(sControlName).Value = vbNullString
            End If
        End With
    End If
End Sub

Lewis

Sorry for the slow reply and thank you very much for your quick answers! Unfortunately I'd left my work PC for the day when they came in but tried them out first thing this morning and both solutions work great! I honestly never knew that frames affected the code so much, guess I need to look a little more in to what they do.

But thank you both so much for your answers, as I said, both of them worked and solved my problem perfectly.