need excel macro, to add two blank rows after a value change, then autosum column C

[dubb]

so the column is:

1
1
1
2
2
2

I want it to do this:
1
1
1
autosum column C

2
2
2



I found a similar one but it does it for column E. I need it for column C and I need to add two rows after every value change.

Sub sbttls()
Dim aArea As Range, i As Integer
i = 0
For Each aArea In ActiveSheet.UsedRange.SpecialCells(xlCellTypeConstants).Areas
i = i + 1
If i <> 1 Then
With Cells(aArea.Row + aArea.Rows.Count, 5)
.Value = WorksheetFunction.Sum(Range(Cells(aArea.Row, 5), Cells(aArea.Row + aArea.Rows.Count - 1, 5)))
With .Font
.ColorIndex = 5
.Bold = True
End With
End With
End If
Next aArea
End Sub

[GC Excel]

Hello and welcome to the forum,

Try this code :

Sub ttls()
    Dim aArea As Range, i As Long, LastRow As Long
    i = 0

    '/Add blank rows
    LastRow = Cells(Rows.Count, 3).End(xlUp).Row
    For i = LastRow To 2 Step -1
        If (Cells(i, 3) <> Cells(i - 1, 3)) Then
            If Cells(i, 3) <> "" And Cells(i - 1, 3) <> "" Then
                Rows(i).EntireRow.Insert
                Rows(i).EntireRow.Insert
            End If
        End If
    Next i

    'Add Sub Total
    i = 0
    For Each aArea In ActiveSheet.UsedRange.SpecialCells(xlCellTypeConstants).Areas
        i = i + 1
        If i <> 1 Then
            With Cells(aArea.Row + aArea.Rows.Count, 3)
                .Value = WorksheetFunction.Sum(Range(Cells(aArea.Row, 3), Cells(aArea.Row + aArea.Rows.Count - 1, 3)))
                With .Font
                    .ColorIndex = 5
                    .Bold = True
                End With
            End With
        End If
    Next aArea
End Sub

[PCI]

Another way
If you don't want the first block to have the SUM, remove the "'" at the beginning of

        'I = I + 1
        'If I <> 1 Then
        'End If

Sub sbttls2()
Dim aArea As Range
Dim LR  As Long, I As Long
Const WkCol As String = "C"

    LR = Range(WkCol & Rows.Count).End(xlUp).Row
    For I = LR To 2 Step -1
        If (Cells(I, WkCol) <> Cells(I - 1, WkCol)) Then
                Cells(I, WkCol).Resize(2, 1).Insert Shift:=xlDown
        End If
    Next I
    
    LR = Range(WkCol & Rows.Count).End(xlUp).Row
    For Each aArea In Range(Cells(1, WkCol), Cells(LR, WkCol)).SpecialCells(xlCellTypeConstants).Areas
        'I = I + 1
        'If I <> 1 Then
            With Cells(aArea.Row + aArea.Rows.Count, WkCol)
                .Formula = "=SUM(R[-" & aArea.Rows.Count & "]C:R[-1]C)"
                With .Font
                .ColorIndex = 5
                .Bold = True
                End With
            End With
        'End If
    Next aArea
End Sub

[JOHN H. DAVIS]

One more:

Sub dubb()
Dim i As Long
For i = Range("C" & Rows.Count).End(3).Row To 2 Step -1
    If Cells(i, "C") <> Cells(i + 1, "C") Then
        Rows(i + 1).Resize(2).Insert
    End If
Next i
For Each numrange In Columns(3).SpecialCells(xlConstants, xlNumbers).Areas
    sumaddr = numrange.Address(False, False)
    numrange.Offset(numrange.Count, 0).Resize(1, 1).Formula = "=SUM(" & sumaddr & ")"
    c = numrange.Count
Next numrange
nodata:
End Sub