Easy macro for copying data to new worksheet

Not as easy as first blush, this macro seems to be giving the desired results:

Option Explicit

Sub UniqueList()
Dim LR As Long

Application.ScreenUpdating = False
With Sheets("List")
    LR = .Range("A" & .Rows.Count).End(xlUp).Row
    With .Range("AA1:AC1")
        .Value = [{"Model.Suffix", "Accessories", "Parent P/N"}]
        .Font.Bold = True
    End With
    With .Range("AA2:AA" & LR)
        .FormulaR1C1 = "=RC2&""|""&RC3"
        .Value = .Value
    End With
    With .Range("AB2:AB" & LR)
        .FormulaR1C1 = "=IF(RC[-1]=R[1]C[-1], RC4&"",""&R[1]C, RC4)"
        .Value = .Value
    End With
    With .Range("AC2:AC" & LR)
        .FormulaR1C1 = "=IF(RC[-2]<>R[-1]C[-2], RC[-1], 0/0)"
        .Value = .Value
    End With
    Application.DisplayAlerts = False
    .Range("AA2:AA" & LR).TextToColumns Destination:=.Range("AA2"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar:="|", _
        FieldInfo:=Array(1, 1), TrailingMinusNumbers:=True
    .Range("AC1").AutoFilter 3, "<>#DIV/0!"
    Sheets("Result").UsedRange.Clear
    .Range("AA1").CurrentRegion.SpecialCells(xlVisible).Copy Sheets("Result").Range("B2")
    .Range("AA:AC").Delete xlShiftToLeft
    With Sheets("Result").Range("B2").CurrentRegion
        .Borders.Weight = xlThin
        .Columns.AutoFit
    End With
End With
Application.ScreenUpdating = True
Sheets("Result").Activate
MsgBox "Updated"
End Sub

As I said, progressively less "easy" as new parameters are added.

This will eliminate the duplicate column C values. As for your second question, when I run the new macro I get those results for that item, so perhaps that issue self-resolved.

Model.Suffix		Accessories	Parent P/N
22LJ620H-ZA.AEKNLBP	AAA74829109	AGF76438301,AGF76453501

Option Explicit

Sub UniqueList()
Dim LR As Long

Application.ScreenUpdating = False
With Sheets("List")
    LR = .Range("A" & .Rows.Count).End(xlUp).Row
    With .Range("AA1:AC1")
        .Value = [{"Model.Suffix", "Accessories", "Parent P/N"}]
        .Font.Bold = True
    End With
    With .Range("AA2:AA" & LR)
        .FormulaR1C1 = "=RC2&""|""&RC3"
        .Value = .Value
    End With
    With .Range("AB2:AB" & LR)
        .FormulaR1C1 = "=IF(RC[-1]=R[1]C[-1], IF(ISNUMBER(SEARCH(RC4, R[1]C)), R[1]C, RC4&"",""&R[1]C), RC4)"
        .Value = .Value
    End With
    With .Range("AC2:AC" & LR)
        .FormulaR1C1 = "=IF(RC[-2]<>R[-1]C[-2], RC[-1], 0/0)"
        .Value = .Value
    End With
    Application.DisplayAlerts = False
    .Range("AA2:AA" & LR).TextToColumns Destination:=.Range("AA2"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar:="|", _
        FieldInfo:=Array(1, 1), TrailingMinusNumbers:=True
    .Range("AC1").AutoFilter 3, "<>#DIV/0!"
    Sheets("Result").UsedRange.Clear
    .Range("AA1").CurrentRegion.SpecialCells(xlVisible).Copy Sheets("Result").Range("B2")
    .Range("AA:AC").Delete xlShiftToLeft
    With Sheets("Result").Range("B2").CurrentRegion
        .Borders.Weight = xlThin
        .Columns.AutoFit
    End With
End With
Application.ScreenUpdating = True
Sheets("Result").Activate
MsgBox "Updated"
End Sub