Print specific number of filtered records

Hello everybody
I have filtered a range according to specific conditions .. The results are more that 100 rows which are visible.
I want to determine 25 record to be printed at every time .. the print will be subsequent
Another point in one of the columns ("ColumnF") I need to add a row to sum the values for these 25 record ..
I know it may be difficult but I will try with your help and I'm sure we can fulfill this target

So to level the understanding of the quest . You want to print 4 pages subtotaling each and totaling the report?
Could you facilitate a sample (not sensitive data) ?

Thanks for quick reply Mr. rcm
Here's a sample .. I put the last row to get the total .. Just last point to print every 25 person and their total ..
I have a code in the attachment

Can anyone help me with that topic?

Maybe an idea you can adapt ?

Added a sheet and copied the filtered data for manipulation.

Thanks a lot Mr. NoSparks

Great idea .. Just last point >> to get the totals for every printed sheet

Thanks a lot
I could add this line at the last loop

.Cells(i, 14).Formula = "=SUBTOTAL(109,N3:N" & i - 1 & ")"

Thanks again for this great help

I failed at some parts to do that ...In case of many pages it doesn't succeed ..
Hope to put the subtotals formulas for every page

How about this ?

    ' sheet to print
    With Sheet2
        .Select
        .Cells(1, 1).Select '<~~ de-selects the copied range
        LastRow = .Cells(Rows.Count, "B").End(xlUp).Row
        .Range(Cells(LastRow, 3), Cells(LastRow, 33)).ClearContents
        
        For i = 28 To .UsedRange.Rows.Count Step 25
            .Cells(i, 1).EntireRow.Insert   '<~~ row for subtotal
            .Cells(i, 14).Formula = "=SUBTOTAL(109,N3:N" & i - 1 & ")"
            .HPageBreaks.Add Before:=Rows(i + 1)
        Next i
        
        'formula for last row
        LastRow = .Cells(Rows.Count, "B").End(xlUp).Row
        .Cells(LastRow, 14).Formula = "=SUBTOTAL(109,N3:N" & LastRow - 1 & ")"
    End With

I've never used subtotal and was surprised they could go in the same column and not be included in the next subtotal. Learn something every day.

I now realize a short coming of this For-Next loop. The .usedrange.rows.count is determined prior to any rows being added so if your printout exceeds 25 pages things will not be right. Should probably be changed to a Do-While loop.

Thanks for offering help
I need to add a formula for each page >>
After applying your great code I got two pages
In N28 I got this formula

=SUBTOTAL(109,N3:N27)

And that's right ..
But in N45 I got this

=SUBTOTAL(109,N3:N44)

And this is not correct . I want it to be like that

=SUBTOTAL(109,N29:N44)

I hope it is clear now

My misunderstanding, you're looking for the sum of each printed page only.
Also corrects number of records on each page, there were only 24 after page 1.
Hope this works.

Option Explicit

Sub PrintSpecfic()
    Dim strCriteria1 As String, strCriteria2 As String
    Dim X As Long, LastRow As Long, StartSum As Long
    Dim i As Integer
    
    strCriteria1 = Sheet1.Range("AH1").Value
    strCriteria2 = Sheet1.Range("AI1").Value
    
    ' clear print sheet
    With Sheet2
        .Select
        .UsedRange.Delete
        .Cells.PageBreak = xlPageBreakNone
        .Cells(1, 1).Select     '<~~ where paste takes place
    End With
    
    ' filter and copy
    On Error Resume Next
    With Sheet1
        .Select
        .AutoFilterMode = False
        .Range("A2:AI2").AutoFilter Field:=34, Criteria1:=strCriteria1
        .Range("A2:AI2").AutoFilter Field:=35, Criteria1:=strCriteria2
        ' Copy relevant range
        .Range("A1:AG" & .Cells(Rows.Count, "B").End(xlUp).Row).SpecialCells(xlCellTypeVisible).Copy
        Sheet2.Paste
        Application.CutCopyMode = False
        .AutoFilterMode = False
    End With
    
    ' sheet to print
    With Sheet2
        .Select
        .Cells(1, 1).Select '<~~ de-selects the copied range
        LastRow = .Cells(Rows.Count, "B").End(xlUp).Row
        .Range(Cells(LastRow, 3), Cells(LastRow, 33)).ClearContents
        
        StartSum = 3
        i = 28  '<~~ first row needing inserted
        Do While i < .UsedRange.Rows.Count
            .Cells(i, 1).EntireRow.Insert   '<~~ row for formulas
            .Cells(i, 14).Formula = "=SUM(N" & StartSum & ":N" & i - 1 & ")"
            .HPageBreaks.Add Before:=Rows(i + 1)
            StartSum = i + 1
            i = i + 26
        Loop

        'formula for last row
        LastRow = .Cells(Rows.Count, "B").End(xlUp).Row
        .Cells(LastRow, 14).Formula = "=SUM(N" & StartSum & ":N" & LastRow - 1 & ")"
    End With
    'ActiveWindow.SelectedSheets.PrintOut Copies:=1
End Sub

Now it is perfect
Thanks a lot for this great help
Thank you very much. You are awesome