Macro to copy specific columns from Multiple worksheets

[Shellybelly]

Anyone knows a macro that can copy specific columns from multiple worksheets and paste it into a summary sheet?. I am working with a large file and I only one specific columns from the different worksheets.
]
eg:

I would like for all values under the header name "Accuracy" to pasted in the summary sheet under the headeer name "accuracy" etc.


Can this be done.

Can anyone help me with this.

[JOHN H. DAVIS]

Maybe:

Sub Shellybellyz()
Dim ws As Worksheet
Dim x As Long
Dim y As Range
Dim z As Long
With Sheets("Summary Sheet")
    Set y = .Rows(1).Find("Accuracy", LookIn:=xlValues, Lookat:=xlWhole)
        If Not y Is Nothing Then z = y.Column
        Set y = Nothing
End With
For Each ws In ActiveWorkbook.Worksheets
If ws.Name <> "Summary Sheet" Then
ws.Activate
    Set y = Rows(1).Find("Accuracy", LookIn:=xlValues, Lookat:=xlWhole)
        If Not y Is Nothing Then
            x = Cells(Rows.Count, ActiveCell.Column).End(3).Row
        Range(Cells(2, ActiveCell.Column), Cells(x, ActiveCell.Column)).Copy Sheets("Summary Sheet").Cells(Rows.Count, z).End(3)(2)
        End If
        Set y = Nothing
End If
Next ws
End Sub

[stnkynts]

Another:

Sub RunMe()
Dim wsSum As Worksheet: Set wsSum = Sheets("Summary")
Dim ws As Worksheet
Dim rFind As Range, rAcc As Range

'Pay attention to capitalization!!!!!

Set rAcc = wsSum.Range(wsSum.Cells(1, 1), wsSum.Cells(1, Columns.Count)).Find("accuracy", , xlValues, xlWhole)

If rAcc Is Nothing Then
    MsgBox ("Could not identify accuracy column in summary sheet")
    Exit Sub
End If

For Each ws In Worksheets
    If ws.Name <> wsSum.Name Then
        Set rFind = ws.Range(ws.Cells(1, 1), ws.Cells(1, Columns.Count)).Find("Accuracy", , xlValues, xlWhole)
        If Not rFind Is Nothing Then
            rFind.Offset(1).Resize(ws.Cells(Rows.Count, rFind.Column).End(xlUp).Row, 1).Copy wsSum.Cells(Rows.Count, rAcc.Column).End(xlUp).Offset(1, 0)
        End If
    End If
Next ws
            
End Sub