Copying files and folders

[LAVA2]

Hi,

There is a folder named "STAR1" in C:\VALUES\ABSTRACTS\VALUES\STAR1

There is a file named "TOTALS.XLSM" in (C:\VALUES\ABSTRACTS\VALUES\STAR1\TOTALS.XLSM)


At "sheet1" of "TOTALS.XLSM" there is a value "1" at cell "K2"



Now, i am looking for a solution to make about 100 copies of "STAR1" and rename each of the copies starting from

"STAR2" in (C:\VALUES\ABSTRACTS\VALUES\STAR2), "STAR3" in (C:\VALUES\ABSTRACTS\VALUES\STAR3) until "STAR100".

And also increase the values at cell "K2" in "TOTALS.XLSM" by 1. so that for folder "STAR2" the value of cell "K2" would be 2 and for "STAR3" it would be 3 etc.

Thanks

[JBeaucaire]

THis should do it:

Option Explicit

Sub MakingCopies()
Dim NUM As Long, fPATH As String, wb As Workbook

Application.ScreenUpdating = False
Application.DisplayAlerts = False
fPATH = "C:\VALUES\ABSTRACTS\VALUES\"                           'the master folder
Set wb = Workbooks.Open(fPATH & "STAR1\Totals.xlsm", False)     'the main workbook to copy
On Error Resume Next

For NUM = 2 To 100
    MkDir fPATH & "STAR" & NUM
    With wb.Sheets("Sheet1").Range("K2")
        .Value = .Value + 1
    End With
    wb.SaveCopyAs fPATH & "STAR" & NUM & "\" & wb.Name
    DoEvents
Next NUM

wb.Close False
Application.ScreenUpdating = True

End Sub

[Alf]

Perhaps something like this?

In order to make it simple I would suggest you add this macro to the file "TOTALS.XLSM" in folder "STAR1" and that "Sheet1" is the active sheet.

Option Explicit

Sub MakeM()

Dim i As Integer
Dim sPath As String

sPath = "C:\VALUES\ABSTRACTS\VALUES\STAR"

For i = 2 To 100

Range("K2") = i

MkDir sPath & i

ActiveWorkbook.SaveAs Filename:=sPath & i & "\" & "Totals.xlsm"

Next

ActiveWorkbook.Close False

End Sub

[Alf]

Thanks for feed back and rep.

Alf