VBA hide row with strikethrough

Dear knowledgeable EF users,

I am currently able to find and replace formatting of cells using the FindFormat function. However, I need the output of this function to hide rows. Does anybody here have a solution?

Private Sub CBYes_Click()

Application.FindFormat.Clear
Application.FindFormat.Interior.Color = RGB(255, 255, 0)
'Application.ReplaceFormat.Interior.ColorIndex = 2
Application.ReplaceFormat.Interior.ColorIndex = xlColorIndexNone
MAIN.Cells.Replace What:="", Replacement:="", SearchFormat:=True, ReplaceFormat:=True

Application.FindFormat.Clear
Application.FindFormat.Font.Strikethrough = True
Application.ActiveCell.EntireRow.Hidden = True
'Application.ActiveCell.MergeArea.EntireRow.Hidden = True
Application.ReplaceFormat.Font.Strikethrough = False
MAIN.Cells.Replace What:="", Replacement:="", SearchFormat:=True, ReplaceFormat:=True

Unload Me

End Sub

Does this help?

Sub ChrisPatterson()
Dim rcell As Range
For Each rcell In ActiveSheet.UsedRange
If rcell.Font.Strikethrough = True Then Rows(rcell.Row).Hidden = True
Next rcell
End Sub

Hi John,

Yes, it certainly does help (with a bit of tweaking in my own code). Thanks very much. It is however a bit slow. Perhaps this is because the sheet it has to go through is nearly 1000 rows long and 22 cells wide? What do you think?

FYI, this is what the code looks like now:

Private Sub CBYes_Click()

Application.ScreenUpdating = False
Application.FindFormat.Clear
Application.FindFormat.Interior.Color = RGB(255, 255, 0)
Application.ReplaceFormat.Interior.ColorIndex = xlColorIndexNone
MAIN.Cells.Replace What:="", Replacement:="", SearchFormat:=True, ReplaceFormat:=True
Application.ReplaceFormat.Clear

Dim rCell As Range
For Each rCell In ActiveSheet.UsedRange
    If rCell.Font.Strikethrough = True Then rows(rCell.Row).Hidden = True
Next rCell

Application.FindFormat.Clear
Application.FindFormat.Font.Strikethrough = True
Application.ReplaceFormat.Font.Strikethrough = False
MAIN.Cells.Replace What:="", Replacement:="", SearchFormat:=True, ReplaceFormat:=True
Application.ReplaceFormat.Clear

Application.ScreenUpdating = True

Unload Me

End Sub

Try:

Sub ChrisPatterson()
Dim rcell As Range
With Application
    .ScreenUpdating = False
    .Calculation = xlCalculationManual
End With
For Each rcell In ActiveSheet.UsedRange
If rcell.Font.Strikethrough = True Then Rows(rcell.Row).Hidden = True
Next rcell
With Application
    .ScreenUpdating = True
    .Calculation = xlCalculationAutomatic
End With
End Sub