delete rows based on three criterias

Hi, try

Sub Marreco_1059651()
Dim startrow As Long
    'starting row number here
    startrow = 2
    ' Assuming data to check is in A Column
    Do Until startrow > Cells(Cells.Rows.Count, "A").End(xlUp).Row
        If Cells(startrow, 2).Value = "Min" Or Cells(startrow, 2).Value = 0 Or Cells(startrow, 2).Value = "" Then
            Rows(startrow).Delete
        Else
            startrow = startrow + 1
        End If
    Loop
End Sub

You can use a filter

Sub Macro1()
    Dim Rws As Long, Rng As Range, fRng As Range
    Rws = Cells(Rows.Count, "B").End(xlUp).Row
    Set fRng = Range(Cells(1, 1), Cells(Rws, 4))
    Set Rng = Range(Cells(2, 1), Cells(Rws, 1))
    Application.ScreenUpdating = False

    fRng.AutoFilter Field:=2, Criteria1:=Array( _
                                         "0", "Min", "="), Operator:=xlFilterValues
    Rng.SpecialCells(xlCellTypeVisible).EntireRow.Delete
    ActiveSheet.AutoFilterMode = 0
End Sub

Or a reverse loop

Sub DeleteRowsReverseLoop()
    Dim lastrow As Long, r As Long
    Application.ScreenUpdating = False

    lastrow = Cells(Rows.Count, "B").End(xlUp).Row

    For r = lastrow To 1 Step -1
        If Cells(r, 2).Value = "0" Or Cells(r, 2).Value = "Min" Or Cells(r, 2).Value = "" Then
            Rows(r).Delete
        End If
    Next r

End Sub